<div style="line-height:1.7;color:#000000;font-size:14px;font-family:arial"><div>code have been pushed, please careful on coding style in future, I flag inline</div><pre><br>At 2015-03-11 13:02:15,aasaipriya@multicorewareinc.com wrote:
># HG changeset patch
># User Aasaipriya Chandran <aasaipriya@multicorewareinc.com>
># Date 1426050128 -19800
>#      Wed Mar 11 10:32:08 2015 +0530
># Node ID 6d22e70191340d11425713bced720a9b4439a27f
># Parent  8bc10baea6d6cbdb15cb9d50d7e98c1560dd5324
>asm : chroma_hps[4x4] for i420 avx2 - improved 336c->214c
>
>diff -r 8bc10baea6d6 -r 6d22e7019134 source/common/x86/asm-primitives.cpp
>--- a/source/common/x86/asm-primitives.cpp     Wed Mar 11 10:29:26 2015 +0530
>+++ b/source/common/x86/asm-primitives.cpp     Wed Mar 11 10:32:08 2015 +0530
>@@ -1577,6 +1577,7 @@
> 
>         p.chroma[X265_CSP_I420].pu[CHROMA_420_32x32].filter_hps = x265_interp_4tap_horiz_ps_32x32_avx2;
>         p.chroma[X265_CSP_I420].pu[CHROMA_420_16x16].filter_hps = x265_interp_4tap_horiz_ps_16x16_avx2;
>+        p.chroma[X265_CSP_I420].pu[CHROMA_420_4x4].filter_hps = x265_interp_4tap_horiz_ps_4x4_avx2;
> 
>         p.chroma[X265_CSP_I422].pu[CHROMA_422_4x4].filter_vpp = x265_interp_4tap_vert_pp_4x4_avx2;
> 
>diff -r 8bc10baea6d6 -r 6d22e7019134 source/common/x86/ipfilter8.asm
>--- a/source/common/x86/ipfilter8.asm  Wed Mar 11 10:29:26 2015 +0530
>+++ b/source/common/x86/ipfilter8.asm  Wed Mar 11 10:32:08 2015 +0530
>@@ -14520,3 +14520,87 @@
>     dec                r6d
>     jnz                .loop
>    RET
>+
>+;-----------------------------------------------------------------------------------------------------------------------------
>+; void interp_4tap_horiz_ps_4x4(pixel *src, intptr_t srcStride, int16_t *dst, intptr_t dstStride, int coeffIdx, int isRowExt)
>+;-----------------------------------------------------------------------------------------------------------------------------
>+INIT_YMM avx2 
>+cglobal interp_4tap_horiz_ps_4x4, 4,7,5
>+    mov             r4d, r4m
>+    mov             r5d, r5m
>+    add             r3d, r3d
>+
>+%ifdef PIC
>+    lea               r6,           [tab_ChromaCoeff]
>+    vpbroadcastd      m0,           [r6 + r4 * 4]
>+%else
>+    vpbroadcastd      m0,           [tab_ChromaCoeff + r4 * 4]
>+%endif
>+
>+    vbroadcasti128     m2,           [pw_1]
>+    vbroadcasti128     m1,           [tab_Tm]
>+
>+    ; register map
>+    ; m0 - interpolate coeff
>+    ; m1 - shuffle order table
>+    ; m2 - constant word 1
>+
>+    dec                r0
>+    test                r5d,       r5d
>+    je                 .label
>+    sub                r0 , r1
</pre><pre>ident above code</pre><pre>>+
>+.label
>+    ; Row 0-1
>+    movu              xm3,           [r0]
>+    vinserti128       m3,           m3,      [r0 + r1],     1
>+    pshufb            m3,           m1
>+    pmaddubsw         m3,           m0
>+    pmaddwd           m3,           m2
>+
>+    ; Row 2-3
>+    lea               r0,           [r0 + r1 * 2]
>+    movu              xm4,           [r0]
>+    vinserti128       m4,           m4,      [r0 + r1],     1
>+    pshufb            m4,           m1
>+    pmaddubsw         m4,           m0
>+    pmaddwd           m4,           m2
>+
>+    packssdw          m3,           m4
>+    psubw             m3,           [pw_2000]
>+    vextracti128      xm4,          m3,     1
>+    movq              [r2],         xm3
>+    movq              [r2+r3],      xm4
>+    lea               r2,           [r2 + r3 * 2]
>+    movhps            [r2],         xm3
>+    movhps            [r2 + r3],    xm4
>+
>+    test                r5d,        r5d
>+    jz                .end
>+    lea               r2,           [r2 + r3 * 2]
>+    lea               r0,           [r0 + r1 * 2]
>+
>+    ;Row 5-6
>+    movu              xm3,          [r0]
>+    vinserti128       m3,           m3,      [r0 + r1],     1
>+    pshufb            m3,           m1
>+    pmaddubsw         m3,           m0
>+    pmaddwd           m3,           m2
>+
>+    ; Row 7
>+    lea               r0,           [r0 + r1 * 2]
>+    vbroadcasti128    m4,           [r0]                      ; [x x x x x A 9 8 7 6 5 4 3 2 1 0]
>+    pshufb            m4,           m1
>+    pmaddubsw         m4,           m0
>+    pmaddwd           m4,           m2
>+
>+    packssdw          m3,           m4
>+    psubw             m3,           [pw_2000]
>+
>+    vextracti128      xm4,          m3,     1
>+    movq              [r2],         xm3
>+    movq              [r2+r3],      xm4
>+    lea               r2,           [r2 + r3 * 2]
>+    movhps            [r2],         xm3
>+.end
>+   RET
>_______________________________________________
>x265-devel mailing list
>x265-devel@videolan.org
>https://mailman.videolan.org/listinfo/x265-devel
</pre></div>