[libdvdnav-devel] [Git][videolan/libdvdread][master] Remove autotools files
Jean-Baptiste Kempf (@jbk)
gitlab at videolan.org
Sat Aug 30 07:19:18 UTC 2025
Jean-Baptiste Kempf pushed to branch master at VideoLAN / libdvdread
Commits:
b4ee99f8 by Jean-Baptiste Kempf at 2025-08-30T09:16:11+02:00
Remove autotools files
- - - - -
4 changed files:
- − Makefile.am
- − configure.ac
- − m4/attributes.m4
- − misc/dvdread.pc.in
Changes:
=====================================
Makefile.am deleted
=====================================
@@ -1,80 +0,0 @@
-ACLOCAL_AMFLAGS = -Im4
-
-AM_CPPFLAGS = -I$(top_srcdir)/src -I$(top_builddir)/src/dvdread $(CSS_CFLAGS)
-
-dist_doc_DATA = AUTHORS ChangeLog COPYING NEWS README.md TODO
-
-MAINTAINERCLEANFILES = ChangeLog
-
-ChangeLog: $(wildcard $(srcdir)/.git/logs/HEAD)
- -cd $(srcdir) && git log > $(abs_builddir)/$(@)-tmp
- -test -s $(@)-tmp && mv $(@)-tmp $(@)
- -rm -f $(@)-tmp
- test -e $(@) || touch $(@)
-
-EXTRA_DIST = msvc doc/footer.html doc/header.html
-
-lib_LTLIBRARIES = libdvdread.la
-
-libdvdread_la_SOURCES = \
- src/bitreader.c \
- src/bswap.h \
- src/dvd_input.c \
- src/dvd_input.h \
- src/dvd_reader.c \
- src/dvd_udf.c \
- src/dvdread_internal.h \
- src/ifo_print.c \
- src/ifo_read.c \
- src/logger.c \
- src/logger.h \
- src/md5.c \
- src/md5.h \
- src/nav_print.c \
- src/nav_read.c \
- msvc/contrib/win32_cs.h
-
-libdvdread_la_LIBADD = $(CSS_LIBS)
-
-libdvdread_la_LDFLAGS = -version-info $(DVDREAD_LTVERSION)
-
-pkgincludedir = $(includedir)/dvdread
-pkginclude_HEADERS = \
- src/dvdread/attributes.h \
- src/dvdread/bitreader.h \
- src/dvdread/dvd_reader.h \
- src/dvdread/dvd_udf.h \
- src/dvdread/ifo_print.h \
- src/dvdread/ifo_read.h \
- src/dvdread/ifo_types.h \
- src/dvdread/nav_print.h \
- src/dvdread/nav_read.h \
- src/dvdread/nav_types.h \
- src/dvdread/version.h
-
-pkgconfigdir = $(libdir)/pkgconfig
-pkgconfig_DATA = misc/dvdread.pc
-
-if APIDOC
-all-local: apidoc
-install-data-local: install-apidoc
-uninstall-hook: uninstall-apidoc
-endif
-
-apidoc: stamp-doxygen
-
-stamp-doxygen: doc/doxygen.cfg
- cd doc && doxygen doxygen.cfg
- touch $@
-
-clean-local:
- -rm -Rf stamp-doxygen doc/html
-
-install-apidoc:
- $(MKDIR_P) $(DESTDIR)$(htmldir)
- for file in doc/html/*; do \
- $(INSTALL_DATA) $$file "$(DESTDIR)$(htmldir)" || exit 1; \
- done;
-
-uninstall-apidoc:
- -rm -Rf $(DESTDIR)$(htmldir)/*.png $(DESTDIR)$(htmldir)/*.html $(DESTDIR)$(htmldir)/*.css $(DESTDIR)$(htmldir)/*.js
=====================================
configure.ac deleted
=====================================
@@ -1,160 +0,0 @@
-dnl library version number
-m4_define([dvdread_major], 7)
-m4_define([dvdread_minor], 0)
-m4_define([dvdread_micro], 0)
-m4_define([dvdread_version],[dvdread_major.dvdread_minor.dvdread_micro])
-
-AC_INIT(libdvdread, dvdread_version)
-
-AC_CONFIG_SRCDIR([src/dvd_reader.c])
-
-AC_PREREQ(2.53)
-AC_CANONICAL_HOST
-
-AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip subdir-objects])
-AM_MAINTAINER_MODE([enable])
-dnl Enable silent rules only when available (automake 1.11 or later).
-m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
-
-LT_INIT
-
-AC_CONFIG_HEADER(config.h)
-AC_CONFIG_MACRO_DIR([m4])
-
-dnl The libtool version numbers (DVDREAD_LT_*); Don't even think about faking this!
-dnl
-dnl immediately before every release do:
-dnl ===================================
-dnl if (the interface is totally unchanged from previous release)
-dnl DVDREAD_LT_REVISION ++;
-dnl else { /* interfaces have been added, removed or changed */
-dnl DVDREAD_LT_REVISION = 0;
-dnl DVDREAD_LT_CURRENT ++;
-dnl if (any interfaces have been _added_ since last release)
-dnl AGE ++;
-dnl if (any interfaces have been _removed_ or _incompatibly changed_)
-dnl AGE = 0;
-dnl }
-dnl
-dnl If you want to know more about what you are doing, here are some details:
-dnl * DVDREAD_LT_CURRENT is the current API version
-dnl * DVDREAD_LT_REVISION is an internal revision number which is increased when the API
-dnl itself did not change
-dnl * DVDREAD_LT_AGE is the number of previous API versions still supported by this library
-dnl * libtool has its own numbering scheme, because local library numbering schemes
-dnl are platform dependent
-dnl * in Linux, the library will be named
-dnl libname.so.(DVDREAD_LT_CURRENT - DVDREAD_LT_AGE).DVDREAD_LT_REVISION.DVDREAD_LT_AGE
-
-DVDREAD_LT_CURRENT=9
-DVDREAD_LT_AGE=1
-DVDREAD_LT_REVISION=0
-
-AC_SUBST([DVDREAD_LTVERSION], [$DVDREAD_LT_CURRENT:$DVDREAD_LT_REVISION:$DVDREAD_LT_AGE])
-
-AC_PROG_CC_C99
-
-dnl C11 static_assert()
-AC_MSG_CHECKING([for _Static_assert])
-AC_LINK_IFELSE([AC_LANG_PROGRAM([], [
-_Static_assert(1, "The impossible happened.");
-])], [
- AC_MSG_RESULT([yes])
- AC_DEFINE([HAVE_STATIC_ASSERT], [1], [Define to 1 if _Static_assert is available.])
-], [
- AC_MSG_RESULT([no])
-])
-
-AC_CHECK_HEADERS_ONCE([sys/param.h limits.h dlfcn.h])
-
-AC_SYS_LARGEFILE
-AC_C_BIGENDIAN
-
-AS_CASE([$host],
- [*mingw32* | *cygwin*], [AC_CHECK_FUNCS(gettimeofday)])
-
-AS_CASE([$host],
- [*-os2-*], LDFLAGS="-no-undefined -Zbin-files $LDFLAGS")
-
-AS_CASE([$host],
- [*-linux-*], [AC_CHECK_FUNCS([getmntent_r])])
-
-AC_ARG_WITH([libdvdcss],
- AS_HELP_STRING([--with-libdvdcss], [Link directly against libdvdcss @<:@default=no@:>@]))
-
-AC_ARG_ENABLE([dlfcn],
- [AS_HELP_STRING([--enable-dlfcn],
- [use builtin dlfcn for mingw (default is auto)])],
- [use_builtin_dlfcn=$enableval],
- [use_builtin_dlfcn=no])
-
-AS_IF([test x"$with_libdvdcss" = "xyes"], [
- CSS_REQUIRES="libdvdcss >= 1.2"
- PKG_CHECK_MODULES([CSS], [$CSS_REQUIRES])
- AC_CHECK_HEADERS([dvdcss/dvdcss.h], [
- AC_DEFINE([HAVE_DVDCSS_DVDCSS_H], [1], [Define to 1 if you have dvdcss/dvdcss.h])
- ], [
- AC_MSG_ERROR([You need libdvdcss (dvdcss.h)])
- ])
- AC_CHECK_HEADERS([dvdcss/dvdcpxm.h], [
- AC_DEFINE([HAVE_DVDCSS_DVDCPXM_H], [1], [Define to 1 if you have dvdcss/dvdcpxm.h])
- ], [
- AC_MSG_WARN([You need libdvdcss >= 1.5 with dvdcpxm.h support])
- ])
-], [
- AS_CASE([$host],
- [*mingw32*], [],
- [use_builtin_dlfcn=no])
-
- AS_IF([test $use_builtin_dlfcn = "yes"], [
- AC_DEFINE([USING_BUILTIN_DLFCN], [1], ["Define to 1 to use builtin dlfcn"])
- ], [
- AC_SEARCH_LIBS([dlopen], [dl])
- ])
-])
-AC_SUBST([CSS_REQUIRES])
-
-CC_CHECK_CFLAGS_APPEND([-Wall -Wsign-compare -Wextra])
-
-dnl Symbol visibility
-CC_CHECK_CFLAGS_APPEND([-fvisibility=hidden])
-CPPFLAGS="${CPPFLAGS} -DDVDREAD_API_EXPORT"
-
-AC_ARG_ENABLE([apidoc],
- AS_HELP_STRING([--disable-apidoc], [Disable building (with Doxygen) and installing API documentation @<:@default=auto@:@>]))
-
-AC_PATH_PROG([DOXYGEN], [doxygen])
-
-AS_IF([test "x$DOXYGEN" = "x"], [
- AS_IF([test "x$enable_apidoc" = "xyes"], [
- AC_MSG_ERROR([You need Doxygen to build API documentation])
- ])
-])
-AM_CONDITIONAL([APIDOC], [test "x$DOXYGEN" != "x" && test "x$enable_apidoc" = "xyes"])
-
-AS_IF([test "x$ac_cv_c_compiler_gnu" = "xyes"], [
- AC_DEFINE([UNUSED], [__attribute__((unused))], [Unused parameter annotation])
-], [
- AC_DEFINE([UNUSED], [], [Unused parameter annotation])
-])
-
-AC_FUNC_STRERROR_R
-AS_IF([test "x$ac_cv_func_strerror_r" = "xyes"], [], [AC_CHECK_FUNCS([strerror_s])])
-
-dnl export library version number
-DVDREAD_VERSION_MAJOR=dvdread_major()
-DVDREAD_VERSION_MINOR=dvdread_minor()
-DVDREAD_VERSION_MICRO=dvdread_micro()
-AC_SUBST(DVDREAD_VERSION_MAJOR)
-AC_SUBST(DVDREAD_VERSION_MINOR)
-AC_SUBST(DVDREAD_VERSION_MICRO)
-
-dnl ---------------------------------------------
-dnl Output configuration files
-dnl ---------------------------------------------
-AC_OUTPUT([
-Makefile
-doc/doxygen.cfg
-misc/dvdread.pc
-src/dvdread/version.h
-])
=====================================
m4/attributes.m4 deleted
=====================================
@@ -1,296 +0,0 @@
-dnl Macros to check the presence of generic (non-typed) symbols.
-dnl Copyright (c) 2006-2007 Diego Pettenò <flameeyes at gmail.com>
-dnl Copyright (c) 2006-2007 xine project
-dnl
-dnl This program is free software; you can redistribute it and/or modify
-dnl it under the terms of the GNU General Public License as published by
-dnl the Free Software Foundation; either version 2, or (at your option)
-dnl any later version.
-dnl
-dnl This program is distributed in the hope that it will be useful,
-dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
-dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
-dnl GNU General Public License for more details.
-dnl
-dnl You should have received a copy of the GNU General Public License
-dnl along with this program; if not, write to the Free Software
-dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
-dnl 02110-1301, USA.
-dnl
-dnl As a special exception, the copyright owners of the
-dnl macro gives unlimited permission to copy, distribute and modify the
-dnl configure scripts that are the output of Autoconf when processing the
-dnl Macro. You need not follow the terms of the GNU General Public
-dnl License when using or distributing such scripts, even though portions
-dnl of the text of the Macro appear in them. The GNU General Public
-dnl License (GPL) does govern all other use of the material that
-dnl constitutes the Autoconf Macro.
-dnl
-dnl This special exception to the GPL applies to versions of the
-dnl Autoconf Macro released by this project. When you make and
-dnl distribute a modified version of the Autoconf Macro, you may extend
-dnl this special exception to the GPL to apply to your modified version as
-dnl well.
-
-dnl Check if the flag is supported by compiler
-dnl CC_CHECK_CFLAGS_SILENT([FLAG], [ACTION-IF-FOUND],[ACTION-IF-NOT-FOUND])
-
-AC_DEFUN([CC_CHECK_CFLAGS_SILENT], [
- AC_CACHE_VAL(AS_TR_SH([cc_cv_cflags_$1]),
- [ac_save_CFLAGS="$CFLAGS"
- CFLAGS="$CFLAGS $1"
- AC_LINK_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
- [eval "AS_TR_SH([cc_cv_cflags_$1])='yes'"],
- [eval "AS_TR_SH([cc_cv_cflags_$1])='no'"])
- CFLAGS="$ac_save_CFLAGS"
- ])
-
- AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_$1])[ = xyes],
- [$2], [$3])
-])
-
-dnl Check if the flag is supported by compiler (cacheable)
-dnl CC_CHECK_CFLAGS([FLAG], [ACTION-IF-FOUND],[ACTION-IF-NOT-FOUND])
-
-AC_DEFUN([CC_CHECK_CFLAGS], [
- AC_CACHE_CHECK([if $CC supports $1 flag],
- AS_TR_SH([cc_cv_cflags_$1]),
- CC_CHECK_CFLAGS_SILENT([$1]) dnl Don't execute actions here!
- )
-
- AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_$1])[ = xyes],
- [$2], [$3])
-])
-
-dnl CC_CHECK_CFLAG_APPEND(FLAG, [action-if-found], [action-if-not-found])
-dnl Check for CFLAG and appends them to CFLAGS if supported
-AC_DEFUN([CC_CHECK_CFLAG_APPEND], [
- AC_CACHE_CHECK([if $CC supports $1 flag],
- AS_TR_SH([cc_cv_cflags_$1]),
- CC_CHECK_CFLAGS_SILENT([$1]) dnl Don't execute actions here!
- )
-
- AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_$1])[ = xyes],
- [CFLAGS="$CFLAGS $1"; $2], [$3])
-])
-
-dnl CC_CHECK_CFLAGS_APPEND([FLAG1 FLAG2], [action-if-found], [action-if-not])
-AC_DEFUN([CC_CHECK_CFLAGS_APPEND], [
- for flag in $1; do
- CC_CHECK_CFLAG_APPEND($flag, [$2], [$3])
- done
-])
-
-dnl Check if the flag is supported by linker (cacheable)
-dnl CC_CHECK_LDFLAGS([FLAG], [ACTION-IF-FOUND],[ACTION-IF-NOT-FOUND])
-
-AC_DEFUN([CC_CHECK_LDFLAGS], [
- AC_CACHE_CHECK([if $CC supports $1 flag],
- AS_TR_SH([cc_cv_ldflags_$1]),
- [ac_save_LDFLAGS="$LDFLAGS"
- LDFLAGS="$LDFLAGS $1"
- AC_LINK_IFELSE([AC_LANG_SOURCE([int main() { return 1; }])],
- [eval "AS_TR_SH([cc_cv_ldflags_$1])='yes'"],
- [eval "AS_TR_SH([cc_cv_ldflags_$1])="])
- LDFLAGS="$ac_save_LDFLAGS"
- ])
-
- AS_IF([eval test x$]AS_TR_SH([cc_cv_ldflags_$1])[ = xyes],
- [$2], [$3])
-])
-
-dnl Check for a -Werror flag or equivalent. -Werror is the GCC
-dnl and ICC flag that tells the compiler to treat all the warnings
-dnl as fatal. We usually need this option to make sure that some
-dnl constructs (like attributes) are not simply ignored.
-dnl
-dnl Other compilers don't support -Werror per se, but they support
-dnl an equivalent flag:
-dnl - Sun Studio compiler supports -errwarn=%all
-AC_DEFUN([CC_CHECK_WERROR], [
- AC_CACHE_CHECK(
- [for $CC way to treat warnings as errors],
- [cc_cv_werror],
- [CC_CHECK_CFLAGS_SILENT([-Werror], [cc_cv_werror=-Werror],
- [CC_CHECK_CFLAGS_SILENT([-errwarn=%all], [cc_cv_werror=-errwarn=%all])])
- ])
-])
-
-AC_DEFUN([CC_CHECK_ATTRIBUTE], [
- AC_REQUIRE([CC_CHECK_WERROR])
- AC_CACHE_CHECK([if $CC supports __attribute__(( ifelse([$2], , [$1], [$2]) ))],
- AS_TR_SH([cc_cv_attribute_$1]),
- [ac_save_CFLAGS="$CFLAGS"
- CFLAGS="$CFLAGS $cc_cv_werror"
- AC_COMPILE_IFELSE([AC_LANG_SOURCE([$3])],
- [eval "AS_TR_SH([cc_cv_attribute_$1])='yes'"],
- [eval "AS_TR_SH([cc_cv_attribute_$1])='no'"])
- CFLAGS="$ac_save_CFLAGS"
- ])
-
- AS_IF([eval test x$]AS_TR_SH([cc_cv_attribute_$1])[ = xyes],
- [AC_DEFINE(
- AS_TR_CPP([SUPPORT_ATTRIBUTE_$1]), 1,
- [Define this if the compiler supports __attribute__(( ifelse([$2], , [$1], [$2]) ))]
- )
- $4],
- [$5])
-])
-
-AC_DEFUN([CC_ATTRIBUTE_CONSTRUCTOR], [
- CC_CHECK_ATTRIBUTE(
- [constructor],,
- [extern void foo();
- void __attribute__((constructor)) ctor() { foo(); }],
- [$1], [$2])
-])
-
-AC_DEFUN([CC_ATTRIBUTE_DESTRUCTOR], [
- CC_CHECK_ATTRIBUTE(
- [destructor],,
- [extern void foo();
- void __attribute__((destructor)) dtor() { foo(); }],
- [$1], [$2])
-])
-
-AC_DEFUN([CC_ATTRIBUTE_FORMAT], [
- CC_CHECK_ATTRIBUTE(
- [format], [format(printf, n, n)],
- [void __attribute__((format(printf, 1, 2))) printflike(const char *fmt, ...) { fmt = (void *)0; }],
- [$1], [$2])
-])
-
-AC_DEFUN([CC_ATTRIBUTE_FORMAT_ARG], [
- CC_CHECK_ATTRIBUTE(
- [format_arg], [format_arg(printf)],
- [char *__attribute__((format_arg(1))) gettextlike(const char *fmt) { fmt = (void *)0; }],
- [$1], [$2])
-])
-
-AC_DEFUN([CC_ATTRIBUTE_VISIBILITY], [
- CC_CHECK_ATTRIBUTE(
- [visibility_$1], [visibility("$1")],
- [void __attribute__((visibility("$1"))) $1_function() { }],
- [$2], [$3])
-])
-
-AC_DEFUN([CC_ATTRIBUTE_NONNULL], [
- CC_CHECK_ATTRIBUTE(
- [nonnull], [nonnull()],
- [void __attribute__((nonnull())) some_function(void *foo, void *bar) { foo = (void*)0; bar = (void*)0; }],
- [$1], [$2])
-])
-
-AC_DEFUN([CC_ATTRIBUTE_UNUSED], [
- CC_CHECK_ATTRIBUTE(
- [unused], ,
- [void some_function(void *foo, __attribute__((unused)) void *bar);],
- [$1], [$2])
-])
-
-AC_DEFUN([CC_ATTRIBUTE_SENTINEL], [
- CC_CHECK_ATTRIBUTE(
- [sentinel], ,
- [void some_function(void *foo, ...) __attribute__((sentinel));],
- [$1], [$2])
-])
-
-AC_DEFUN([CC_ATTRIBUTE_DEPRECATED], [
- CC_CHECK_ATTRIBUTE(
- [deprecated], ,
- [void some_function(void *foo, ...) __attribute__((deprecated));],
- [$1], [$2])
-])
-
-AC_DEFUN([CC_ATTRIBUTE_ALIAS], [
- CC_CHECK_ATTRIBUTE(
- [alias], [weak, alias],
- [void other_function(void *foo) { }
- void some_function(void *foo) __attribute__((weak, alias("other_function")));],
- [$1], [$2])
-])
-
-AC_DEFUN([CC_ATTRIBUTE_MALLOC], [
- CC_CHECK_ATTRIBUTE(
- [malloc], ,
- [void * __attribute__((malloc)) my_alloc(int n);],
- [$1], [$2])
-])
-
-AC_DEFUN([CC_ATTRIBUTE_PACKED], [
- CC_CHECK_ATTRIBUTE(
- [packed], ,
- [struct astructure { char a; int b; long c; void *d; } __attribute__((packed));
- char assert@<:@(sizeof(struct astructure) == (sizeof(char)+sizeof(int)+sizeof(long)+sizeof(void*)))-1@:>@;],
- [$1], [$2])
-])
-
-AC_DEFUN([CC_ATTRIBUTE_CONST], [
- CC_CHECK_ATTRIBUTE(
- [const], ,
- [int __attribute__((const)) twopow(int n) { return 1 << n; } ],
- [$1], [$2])
-])
-
-AC_DEFUN([CC_FLAG_VISIBILITY], [
- AC_REQUIRE([CC_CHECK_WERROR])
- AC_CACHE_CHECK([if $CC supports -fvisibility=hidden],
- [cc_cv_flag_visibility],
- [cc_flag_visibility_save_CFLAGS="$CFLAGS"
- CFLAGS="$CFLAGS $cc_cv_werror"
- CC_CHECK_CFLAGS_SILENT([-fvisibility=hidden],
- cc_cv_flag_visibility='yes',
- cc_cv_flag_visibility='no')
- CFLAGS="$cc_flag_visibility_save_CFLAGS"])
-
- AS_IF([test "x$cc_cv_flag_visibility" = "xyes"],
- [AC_DEFINE([SUPPORT_FLAG_VISIBILITY], 1,
- [Define this if the compiler supports the -fvisibility flag])
- $1],
- [$2])
-])
-
-AC_DEFUN([CC_FUNC_EXPECT], [
- AC_REQUIRE([CC_CHECK_WERROR])
- AC_CACHE_CHECK([if compiler has __builtin_expect function],
- [cc_cv_func_expect],
- [ac_save_CFLAGS="$CFLAGS"
- CFLAGS="$CFLAGS $cc_cv_werror"
- AC_COMPILE_IFELSE(
- [int some_function() {
- int a = 3;
- return (int)__builtin_expect(a, 3);
- }],
- [cc_cv_func_expect=yes],
- [cc_cv_func_expect=no])
- CFLAGS="$ac_save_CFLAGS"
- ])
-
- AS_IF([test "x$cc_cv_func_expect" = "xyes"],
- [AC_DEFINE([SUPPORT__BUILTIN_EXPECT], 1,
- [Define this if the compiler supports __builtin_expect() function])
- $1],
- [$2])
-])
-
-AC_DEFUN([CC_ATTRIBUTE_ALIGNED], [
- AC_REQUIRE([CC_CHECK_WERROR])
- AC_CACHE_CHECK([highest __attribute__ ((aligned ())) supported],
- [cc_cv_attribute_aligned],
- [ac_save_CFLAGS="$CFLAGS"
- CFLAGS="$CFLAGS $cc_cv_werror"
- for cc_attribute_align_try in 64 32 16 8 4 2; do
- AC_COMPILE_IFELSE([
- int main() {
- static char c __attribute__ ((aligned($cc_attribute_align_try))) = 0;
- return c;
- }], [cc_cv_attribute_aligned=$cc_attribute_align_try; break])
- done
- CFLAGS="$ac_save_CFLAGS"
- ])
-
- if test "x$cc_cv_attribute_aligned" != "x"; then
- AC_DEFINE_UNQUOTED([ATTRIBUTE_ALIGNED_MAX], [$cc_cv_attribute_aligned],
- [Define the highest alignment supported])
- fi
-])
=====================================
misc/dvdread.pc.in deleted
=====================================
@@ -1,13 +0,0 @@
-prefix=@prefix@
-exec_prefix=@exec_prefix@
-libdir=@libdir@
-includedir=@includedir@
-
-Name: libdvdread
-Description: Low level DVD access library
-Version: @VERSION@
-
-Requires.private: @CSS_REQUIRES@
-
-Cflags: -I${includedir}
-Libs: -L${libdir} -ldvdread
View it on GitLab: https://code.videolan.org/videolan/libdvdread/-/commit/b4ee99f8211d8afc67b15a744b494f30251aa741
--
View it on GitLab: https://code.videolan.org/videolan/libdvdread/-/commit/b4ee99f8211d8afc67b15a744b494f30251aa741
You're receiving this email because of your account on code.videolan.org.
VideoLAN code repository instance
More information about the libdvdnav-devel
mailing list