[x265] [PATCH Review Only] filterHorizontal_p_p_4, 8x8 asm code

[praveen at multicorewareinc.com]

# HG changeset patch
# User praveen Tiwari
# Date 1381211608 -19800
# Node ID 5d8d2f4ae188022372fe0282c5eef4c8336e7d37
# Parent  d9580d9cad8df6ad00d08ab538cdac27c0eb4e92
filterHorizontal_p_p_4, 8x8 asm code

diff -r d9580d9cad8d -r 5d8d2f4ae188 source/common/x86/ipfilter8.asm
--- a/source/common/x86/ipfilter8.asm	Tue Oct 08 11:08:01 2013 +0530
+++ b/source/common/x86/ipfilter8.asm	Tue Oct 08 11:23:28 2013 +0530
@@ -183,3 +183,61 @@
     FILTER_H4_w4   x0, x1, x2
     movd        [dstq],    x1
     RET
+
+SECTION_RODATA 32
+tab_Tm:     db 0, 1, 2, 3, 1, 2, 3, 4, 2, 3, 4, 5, 3, 4, 5, 6
+            db 4, 5, 6, 7, 5, 6, 7, 8, 6, 7, 8, 9, 7, 8, 9, 10
+
+tab_c_512:  times 8 dw 512
+
+SECTION .text
+
+%macro FILTER_H4_w8 3
+    movu        %1, [srcq - 1]
+    pshufb      %2, %1, Tm0
+    pmaddubsw   %2, coef2
+    pshufb      %1, %1, Tm1
+    pmaddubsw   %1, coef2
+    phaddw      %2, %1
+    pmulhrsw    %2, %3
+    packuswb    %2, %2
+%endmacro
+
+%macro FILTER_H4_w8_CALL 0
+    FILTER_H4_w8   x0, x1, x2
+
+    movh        [dstq],      x1
+
+    add         srcq,        srcstrideq
+    add         dstq,        dststrideq
+%endmacro
+
+;-----------------------------------------------------------------------------
+; void filterHorizontal_p_p_4(pixel *src, intptr_t srcStride, pixel *dst, intptr_t dstStride, int width, int height, short const *coeff)
+;-----------------------------------------------------------------------------
+INIT_XMM sse4
+cglobal filterHorizontal_p_p_4, 4, 5, 6, src, srcstride, dst, dststride
+%define coef2       m5
+%define Tm0         m4
+%define Tm1         m3
+%define x2          m2
+%define x1          m1
+%define x0          m0
+
+    mov         r4,         r6m
+    movu        coef2,      [r4]
+    packsswb    coef2,      coef2
+    pshufd      coef2,      coef2,      0
+
+    mova        x2,         [tab_c_512]
+
+    mova        Tm0,        [tab_Tm]
+    mova        Tm1,        [tab_Tm + 16]
+
+ %rep 7
+ FILTER_H4_w8_CALL
+ %endrep
+
+    FILTER_H4_w8   x0, x1, x2
+    movh        [dstq],    x1
+    RET