[x265] [PATCH Review Only] Luma_hpp[64x64 , 64x48 , 64x32 , 64x16] avx2 asm code : improved 33137c->22606c , 24826c->17202c , 16726c->11560c , 7830c->5534c

[aasaipriya at multicorewareinc.com]

# HG changeset patch
# User Aasaipriya Chandran <aasaipriya at multicorewareinc.com>
# Date 1416391573 -19800
#      Wed Nov 19 15:36:13 2014 +0530
# Node ID 3475a4a465bdbe9e2c1a9993de32e9ff1354ffe8
# Parent  6c307cb8d126f9571154ffa0db65bd7f41fab70b
Luma_hpp[64x64 , 64x48 , 64x32 , 64x16] avx2 asm code : improved 33137c->22606c , 24826c->17202c , 16726c->11560c , 7830c->5534c

diff -r 6c307cb8d126 -r 3475a4a465bd source/common/x86/ipfilter8.asm
--- a/source/common/x86/ipfilter8.asm	Wed Nov 19 15:25:39 2014 +0530
+++ b/source/common/x86/ipfilter8.asm	Wed Nov 19 15:36:13 2014 +0530
@@ -1035,6 +1035,117 @@
     RET
 
 
+%macro IPFILTER_LUMA_64x_avx2 2
+INIT_YMM avx2
+cglobal interp_8tap_horiz_pp_%1x%2, 4,6,8
+    sub             r0, 3
+    mov             r4d, r4m
+%ifdef PIC
+    lea             r5, [tab_LumaCoeff]
+    vpbroadcastd    m0, [r5 + r4 * 8]
+    vpbroadcastd    m1, [r5 + r4 * 8 + 4]
+%else
+    vpbroadcastd    m0, [tab_LumaCoeff + r4 * 8]
+    vpbroadcastd    m1, [tab_LumaCoeff + r4 * 8 + 4]
+%endif
+    ;mova            m2, [tab_Tm]
+    movu            m3, [tab_Tm + 16]
+    vpbroadcastd    m7, [pw_1]
+
+    ; register map
+    ; m0 , m1 interpolate coeff
+    ; m2 , m2  shuffle order table
+    ; m7 - pw_1
+
+    mov             r4d,  %2
+.loop:
+    ; Row 0
+    vbroadcasti128  m4, [r0]                        ; [x E D C B A 9 8 7 6 5 4 3 2 1 0]
+    pshufb          m5, m4, m3
+    pshufb          m4, [tab_Tm]
+    pmaddubsw       m4, m0
+    pmaddubsw       m5, m1
+    paddw           m4, m5
+    pmaddwd         m4, m7
+    vbroadcasti128  m5, [r0 + 8]                    
+    pshufb          m6, m5, m3
+    pshufb          m5, [tab_Tm]
+    pmaddubsw       m5, m0
+    pmaddubsw       m6, m1
+    paddw           m5, m6
+    pmaddwd         m5, m7
+    packssdw        m4, m5                          ; [17 16 15 14 07 06 05 04 13 12 11 10 03 02 01 00]
+    pmulhrsw        m4, [pw_512]
+    vbroadcasti128  m2, [r0 + 16]               
+    pshufb          m5, m2, m3
+    pshufb          m2, [tab_Tm]
+    pmaddubsw       m2, m0
+    pmaddubsw       m5, m1
+    paddw           m2, m5
+    pmaddwd         m2, m7
+    vbroadcasti128  m5, [r0 + 24]                   
+    pshufb          m6, m5, m3
+    pshufb          m5, [tab_Tm]
+    pmaddubsw       m5, m0
+    pmaddubsw       m6, m1
+    paddw           m5, m6
+    pmaddwd         m5, m7
+    packssdw        m2, m5
+    pmulhrsw        m2, [pw_512]
+    packuswb        m4,   m2
+    vpermq          m4,   m4, 11011000b
+    vextracti128    xm5,  m4, 1
+    pshufd          xm4,  xm4, 11011000b
+    pshufd          xm5,  xm5, 11011000b
+    movu            [r2], xm4
+    movu            [r2 + 16],xm5
+
+    vbroadcasti128  m4, [r0 + 32]
+    pshufb          m5, m4, m3
+    pshufb          m4, [tab_Tm]
+    pmaddubsw       m4, m0
+    pmaddubsw       m5, m1
+    paddw           m4, m5
+    pmaddwd         m4, m7
+    vbroadcasti128  m5, [r0 + 40]
+    pshufb          m6, m5, m3
+    pshufb          m5, [tab_Tm]
+    pmaddubsw       m5, m0
+    pmaddubsw       m6, m1
+    paddw           m5, m6
+    pmaddwd         m5, m7
+    packssdw        m4, m5 
+    pmulhrsw        m4, [pw_512]
+    vbroadcasti128  m2, [r0 + 48]
+    pshufb          m5, m2, m3
+    pshufb          m2, [tab_Tm]
+    pmaddubsw       m2, m0
+    pmaddubsw       m5, m1
+    paddw           m2, m5
+    pmaddwd         m2, m7
+    vbroadcasti128  m5, [r0 + 56]
+    pshufb          m6, m5, m3
+    pshufb          m5, [tab_Tm]
+    pmaddubsw       m5, m0
+    pmaddubsw       m6, m1
+    paddw           m5, m6
+    pmaddwd         m5, m7
+    packssdw        m2, m5
+    pmulhrsw        m2, [pw_512]
+    packuswb        m4,   m2
+    vpermq          m4,   m4, 11011000b
+    vextracti128    xm5,  m4, 1
+    pshufd          xm4,  xm4, 11011000b
+    pshufd          xm5,  xm5, 11011000b
+    movu            [r2 +32], xm4
+    movu            [r2 + 48],xm5
+    lea             r0, [r0 + r1]
+    lea             r2, [r2 + r3]
+    dec             r4d
+    jnz             .loop
+    RET
+
+
 ;--------------------------------------------------------------------------------------------------------------
 ; void interp_8tap_horiz_pp_%1x%2(pixel *src, intptr_t srcStride, pixel *dst, intptr_t dstStride, int coeffIdx)
 ;--------------------------------------------------------------------------------------------------------------
@@ -1053,7 +1164,10 @@
     IPFILTER_LUMA_32x_avx2 32 , 16
     IPFILTER_LUMA_32x_avx2 32 , 64
 
-    
+    IPFILTER_LUMA_64x_avx2 64 , 64
+    IPFILTER_LUMA_64x_avx2 64 , 48
+    IPFILTER_LUMA_64x_avx2 64 , 32
+    IPFILTER_LUMA_64x_avx2 64 , 16
 
 ;--------------------------------------------------------------------------------------------------------------
 ; void interp_8tap_horiz_pp_%1x%2(pixel *src, intptr_t srcStride, pixel *dst, intptr_t dstStride, int coeffIdx)