[x265] [PATCH] asm: chroma_hps[64x64, 64x48, 64x32, 64x16] for i444 - improved 21540c->14767c, 18551c->14129c, 17096c->12742c, 6216c->3923c
aasaipriya at multicorewareinc.com
aasaipriya at multicorewareinc.com
Thu Apr 16 11:36:50 CEST 2015
# HG changeset patch
# User Aasaipriya Chandran <aasaipriya at multicorewareinc.com>
# Date 1429174721 -19800
# Thu Apr 16 14:28:41 2015 +0530
# Node ID 59dd5944e4cfe16bd878e8ef71978d18b6ce6808
# Parent 7be1172ec816298c32f588908e1b6f0fa214d349
asm: chroma_hps[64x64, 64x48, 64x32, 64x16] for i444 - improved 21540c->14767c, 18551c->14129c,17096c->12742c, 6216c->3923c
diff -r 7be1172ec816 -r 59dd5944e4cf source/common/x86/asm-primitives.cpp
--- a/source/common/x86/asm-primitives.cpp Thu Apr 16 11:38:32 2015 +0530
+++ b/source/common/x86/asm-primitives.cpp Thu Apr 16 14:28:41 2015 +0530
@@ -2186,6 +2186,12 @@
p.chroma[X265_CSP_I422].pu[CHROMA_422_24x64].filter_hpp = x265_interp_4tap_horiz_pp_24x64_avx2;
p.chroma[X265_CSP_I422].pu[CHROMA_422_2x16].filter_hpp = x265_interp_4tap_horiz_pp_2x16_avx2;
+ //i444 chroma_hps
+ p.chroma[X265_CSP_I444].pu[LUMA_64x32].filter_hps = x265_interp_4tap_horiz_ps_64x32_avx2;
+ p.chroma[X265_CSP_I444].pu[LUMA_64x48].filter_hps = x265_interp_4tap_horiz_ps_64x48_avx2;
+ p.chroma[X265_CSP_I444].pu[LUMA_64x16].filter_hps = x265_interp_4tap_horiz_ps_64x16_avx2;
+ p.chroma[X265_CSP_I444].pu[LUMA_64x64].filter_hps = x265_interp_4tap_horiz_ps_64x64_avx2;
+
if ((cpuMask & X265_CPU_BMI1) && (cpuMask & X265_CPU_BMI2))
p.findPosLast = x265_findPosLast_x64;
}
diff -r 7be1172ec816 -r 59dd5944e4cf source/common/x86/ipfilter8.asm
--- a/source/common/x86/ipfilter8.asm Thu Apr 16 11:38:32 2015 +0530
+++ b/source/common/x86/ipfilter8.asm Thu Apr 16 14:28:41 2015 +0530
@@ -2144,6 +2144,108 @@
RET
;-----------------------------------------------------------------------------------------------------------------------------
+; void interp_4tap_horiz_ps_64xN(pixel *src, intptr_t srcStride, int16_t *dst, intptr_t dstStride, int coeffIdx, int isRowExt)
+;-----------------------------------------------------------------------------------------------------------------------------;
+%macro IPFILTER_CHROMA_HPS_64xN 1
+INIT_YMM avx2
+cglobal interp_4tap_horiz_ps_64x%1, 4,7,6
+ mov r4d, r4m
+ mov r5d, r5m
+ add r3d, r3d
+
+%ifdef PIC
+ lea r6, [tab_ChromaCoeff]
+ vpbroadcastd m0, [r6 + r4 * 4]
+%else
+ vpbroadcastd m0, [tab_ChromaCoeff + r4 * 4]
+%endif
+
+ vbroadcasti128 m2, [pw_1]
+ vbroadcasti128 m5, [pw_2000]
+ mova m1, [tab_Tm]
+
+ ; register map
+ ; m0 - interpolate coeff
+ ; m1 - shuffle order table
+ ; m2 - constant word 1
+ mov r6d, %1
+ dec r0
+ test r5d, r5d
+ je .loop
+ sub r0 , r1
+ add r6d , 3
+
+.loop
+ ; Row 0
+ vbroadcasti128 m3, [r0] ; [x x x x x A 9 8 7 6 5 4 3 2 1 0]
+ pshufb m3, m1
+ pmaddubsw m3, m0
+ pmaddwd m3, m2
+ vbroadcasti128 m4, [r0 + 8] ; [x x x x x A 9 8 7 6 5 4 3 2 1 0]
+ pshufb m4, m1
+ pmaddubsw m4, m0
+ pmaddwd m4, m2
+
+ packssdw m3, m4
+ psubw m3, m5
+ vpermq m3, m3, 11011000b
+ movu [r2], m3
+
+ vbroadcasti128 m3, [r0 + 16] ; [x x x x x A 9 8 7 6 5 4 3 2 1 0]
+ pshufb m3, m1
+ pmaddubsw m3, m0
+ pmaddwd m3, m2
+ vbroadcasti128 m4, [r0 + 24] ; [x x x x x A 9 8 7 6 5 4 3 2 1 0]
+ pshufb m4, m1
+ pmaddubsw m4, m0
+ pmaddwd m4, m2
+
+ packssdw m3, m4
+ psubw m3, m5
+ vpermq m3, m3, 11011000b
+ movu [r2 + 32], m3
+
+ vbroadcasti128 m3, [r0 + 32] ; [x x x x x A 9 8 7 6 5 4 3 2 1 0]
+ pshufb m3, m1
+ pmaddubsw m3, m0
+ pmaddwd m3, m2
+ vbroadcasti128 m4, [r0 + 40] ; [x x x x x A 9 8 7 6 5 4 3 2 1 0]
+ pshufb m4, m1
+ pmaddubsw m4, m0
+ pmaddwd m4, m2
+
+ packssdw m3, m4
+ psubw m3, m5
+ vpermq m3, m3, 11011000b
+ movu [r2 + 64], m3
+
+ vbroadcasti128 m3, [r0 + 48] ; [x x x x x A 9 8 7 6 5 4 3 2 1 0]
+ pshufb m3, m1
+ pmaddubsw m3, m0
+ pmaddwd m3, m2
+ vbroadcasti128 m4, [r0 + 56] ; [x x x x x A 9 8 7 6 5 4 3 2 1 0]
+ pshufb m4, m1
+ pmaddubsw m4, m0
+ pmaddwd m4, m2
+
+ packssdw m3, m4
+ psubw m3, m5
+ vpermq m3, m3, 11011000b
+ movu [r2 + 96], m3
+
+ add r2, r3
+ add r0, r1
+ dec r6d
+ jnz .loop
+ RET
+%endmacro
+
+ IPFILTER_CHROMA_HPS_64xN 64
+ IPFILTER_CHROMA_HPS_64xN 32
+ IPFILTER_CHROMA_HPS_64xN 48
+ IPFILTER_CHROMA_HPS_64xN 16
+
+;-----------------------------------------------------------------------------------------------------------------------------
;void interp_horiz_ps_c(const pixel* src, intptr_t srcStride, int16_t* dst, intptr_t dstStride, int coeffIdx, int isRowExt)
;-----------------------------------------------------------------------------------------------------------------------------
diff -r 7be1172ec816 -r 59dd5944e4cf source/common/x86/ipfilter8.h
--- a/source/common/x86/ipfilter8.h Thu Apr 16 11:38:32 2015 +0530
+++ b/source/common/x86/ipfilter8.h Thu Apr 16 14:28:41 2015 +0530
@@ -696,7 +696,7 @@
CHROMA_444_FILTERS(_sse4);
CHROMA_444_SP_FILTERS(_sse4);
CHROMA_444_SS_FILTERS(_sse2);
-
+CHROMA_444_FILTERS(_avx2);
#undef SETUP_CHROMA_FUNC_DEF
#undef SETUP_CHROMA_SP_FUNC_DEF
More information about the x265-devel
mailing list