[x265] [PATCH] asm: intrapred dc8 sse2
chen
chenm003 at 163.com
Sat Feb 28 03:27:44 CET 2015
it's right now.
At 2015-02-28 06:58:02,dtyx265 at gmail.com wrote:
># HG changeset patch
># User David T Yuen <dtyx265 at gmail.com>
># Date 1425077816 28800
># Node ID ff2b3397092367123e936957cd57a9dd2985b03f
># Parent 018e8bbaa854b1a4bd82b3a2e23f7775a77da5cc
>asm: intrapred dc8 sse2
>
>This replaces c code for systems using ssse3 to sse2 processors
>The code is backported from intrapred dc8 sse4
>
>./test/TestBench --testbench intrapred | grep 8x8
>intra_dc_8x8[f=0] 3.86x 235.11 906.74
>intra_dc_8x8[f=1] 2.31x 555.00 1280.00
>
>and supports 32 bit
>
>./test/TestBench --testbench intrapred | grep 8x8
>intra_dc_8x8[f=0] 3.86x 235.21 906.81
>intra_dc_8x8[f=1] 2.37x 539.99 1279.99
>
>and a white space nit in intrapred.h
>
>diff -r 018e8bbaa854 -r ff2b33970923 source/common/x86/asm-primitives.cpp
>--- a/source/common/x86/asm-primitives.cpp Fri Feb 27 11:46:09 2015 +0530
>+++ b/source/common/x86/asm-primitives.cpp Fri Feb 27 14:56:56 2015 -0800
>@@ -1205,6 +1205,7 @@
> ALL_LUMA_TU_S(ssd_s, pixel_ssd_s_, sse2);
>
> p.cu[BLOCK_4x4].intra_pred[DC_IDX] = x265_intra_pred_dc4_sse2;
>+ p.cu[BLOCK_8x8].intra_pred[DC_IDX] = x265_intra_pred_dc8_sse2;
>
> p.cu[BLOCK_4x4].calcresidual = x265_getResidual4_sse2;
> p.cu[BLOCK_8x8].calcresidual = x265_getResidual8_sse2;
>diff -r 018e8bbaa854 -r ff2b33970923 source/common/x86/intrapred.h
>--- a/source/common/x86/intrapred.h Fri Feb 27 11:46:09 2015 +0530
>+++ b/source/common/x86/intrapred.h Fri Feb 27 14:56:56 2015 -0800
>@@ -26,8 +26,9 @@
> #ifndef X265_INTRAPRED_H
> #define X265_INTRAPRED_H
>
>-void x265_intra_pred_dc4_sse2 (pixel* dst, intptr_t dstStride, const pixel*srcPix, int, int filter);
>-void x265_intra_pred_dc4_sse4 (pixel* dst, intptr_t dstStride, const pixel*srcPix, int, int filter);
>+void x265_intra_pred_dc4_sse2(pixel* dst, intptr_t dstStride, const pixel*srcPix, int, int filter);
>+void x265_intra_pred_dc8_sse2(pixel* dst, intptr_t dstStride, const pixel*srcPix, int, int filter);
>+void x265_intra_pred_dc4_sse4(pixel* dst, intptr_t dstStride, const pixel*srcPix, int, int filter);
> void x265_intra_pred_dc8_sse4(pixel* dst, intptr_t dstStride, const pixel* srcPix, int, int filter);
> void x265_intra_pred_dc16_sse4(pixel* dst, intptr_t dstStride, const pixel* srcPix, int, int filter);
> void x265_intra_pred_dc32_sse4(pixel* dst, intptr_t dstStride, const pixel* srcPix, int, int filter);
>diff -r 018e8bbaa854 -r ff2b33970923 source/common/x86/intrapred8.asm
>--- a/source/common/x86/intrapred8.asm Fri Feb 27 11:46:09 2015 +0530
>+++ b/source/common/x86/intrapred8.asm Fri Feb 27 14:56:56 2015 -0800
>@@ -117,6 +117,7 @@
>
> SECTION .text
>
>+cextern pw_2
> cextern pw_4
> cextern pw_8
> cextern pw_16
>@@ -207,6 +208,92 @@
> ;---------------------------------------------------------------------------------------------
> ; void intra_pred_dc(pixel* dst, intptr_t dstStride, pixel *srcPix, int dirMode, int bFilter)
> ;---------------------------------------------------------------------------------------------
>+INIT_XMM sse2
>+cglobal intra_pred_dc8, 5, 7, 3
>+ pxor m0, m0
>+ movh m1, [r2 + 1]
>+ movh m2, [r2 + 17]
>+ punpcklqdq m1, m2
>+ psadbw m1, m0
>+ pshufd m2, m1, 2
>+ paddw m1, m2
>+
>+ paddw m1, [pw_8]
>+ psraw m1, 4
>+ pmullw m1, [pw_257]
>+ pshuflw m1, m1, 0x00 ; m1 = byte [dc_val ...]
>+
>+ test r4d, r4d
>+
>+ ; store DC 8x8
>+ lea r6, [r1 + r1 * 2]
>+ lea r5, [r6 + r1 * 2]
>+ movh [r0], m1
>+ movh [r0 + r1], m1
>+ movh [r0 + r1 * 2], m1
>+ movh [r0 + r6], m1
>+ movh [r0 + r1 * 4], m1
>+ movh [r0 + r5], m1
>+ movh [r0 + r6 * 2], m1
>+ lea r5, [r5 + r1 * 2]
>+ movh [r0 + r5], m1
>+
>+ ; Do DC Filter
>+ jz .end
>+ psrlw m1, 8
>+ movq m2, [pw_2]
>+ pmullw m2, m1
>+ paddw m2, [pw_2]
>+ movd r4d, m2 ; r4d = DC * 2 + 2
>+ paddw m1, m2 ; m1 = DC * 3 + 2
>+ pshufd m1, m1, 0
>+
>+ ; filter top
>+ movq m2, [r2 + 1]
>+ punpcklbw m2, m0
>+ paddw m2, m1
>+ psraw m2, 2 ; sum = sum / 16
>+ packuswb m2, m2
>+ movh [r0], m2
>+
>+ ; filter top-left
>+ movzx r3d, byte [r2 + 17]
>+ add r4d, r3d
>+ movzx r3d, byte [r2 + 1]
>+ add r3d, r4d
>+ shr r3d, 2
>+ mov [r0], r3b
>+
>+ ; filter left
>+ movq m2, [r2 + 18]
>+ punpcklbw m2, m0
>+ paddw m2, m1
>+ psraw m2, 2
>+ packuswb m2, m2
>+ movd r2d, m2
>+ lea r0, [r0 + r1]
>+ lea r5, [r6 + r1 * 2]
>+ mov [r0], r2b
>+ shr r2, 8
>+ mov [r0 + r1], r2b
>+ shr r2, 8
>+ mov [r0 + r1 * 2], r2b
>+ shr r2, 8
>+ mov [r0 + r6], r2b
>+ pshufd m2, m2, 0x01
>+ movd r2d, m2
>+ mov [r0 + r1 * 4], r2b
>+ shr r2, 8
>+ mov [r0 + r5], r2b
>+ shr r2, 8
>+ mov [r0 + r6 * 2], r2b
>+
>+.end:
>+ RET
>+
>+;---------------------------------------------------------------------------------------------
>+; void intra_pred_dc(pixel* dst, intptr_t dstStride, pixel *srcPix, int dirMode, int bFilter)
>+;---------------------------------------------------------------------------------------------
> INIT_XMM sse4
> cglobal intra_pred_dc4, 5,5,3
> inc r2
>_______________________________________________
>x265-devel mailing list
>x265-devel at videolan.org
>https://mailman.videolan.org/listinfo/x265-devel
-------------- next part --------------
An HTML attachment was scrubbed...
URL: <http://mailman.videolan.org/pipermail/x265-devel/attachments/20150228/d5b66700/attachment-0001.html>
More information about the x265-devel
mailing list