[x265] [PATCH] asm: avx2 code for chroma_vpp/vsp/vps/vss[4x8][i420] 16bpp
aasaipriya at multicorewareinc.com
aasaipriya at multicorewareinc.com
Thu Jun 11 08:56:39 CEST 2015
# HG changeset patch
# User Aasaipriya Chandran <aasaipriya at multicorewareinc.com>
# Date 1434005756 -19800
# Thu Jun 11 12:25:56 2015 +0530
# Node ID d4cd5ae54e4b5670ff28236b9d6afee403a34bcc
# Parent 64fcb3fcde5a93b4966684ab22fef54b85e93152
asm: avx2 code for chroma_vpp/vsp/vps/vss[4x8][i420] 16bpp
avx2:
chroma_vpp[ 4x8] 7.82x 332.42 2598.15
chroma_vps[ 4x8] 6.03x 328.44 1981.81
chroma_vsp[ 4x8] 7.73x 309.47 2393.53
chroma_vss[ 4x8] 6.26x 284.96 1782.53
sse:
chroma_vpp[ 4x8] 3.65x 710.78 2595.22
chroma_vps[ 4x8] 3.33x 660.05 2195.90
chroma_vsp[ 4x8] 3.46x 719.83 2493.53
chroma_vss[ 4x8] 3.05x 641.95 1956.22
diff -r 64fcb3fcde5a -r d4cd5ae54e4b source/common/x86/asm-primitives.cpp
--- a/source/common/x86/asm-primitives.cpp Thu Jun 11 11:59:05 2015 +0530
+++ b/source/common/x86/asm-primitives.cpp Thu Jun 11 12:25:56 2015 +0530
@@ -1714,6 +1714,10 @@
p.chroma[X265_CSP_I420].pu[CHROMA_420_4x4].filter_vps = x265_interp_4tap_vert_ps_4x4_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_4x4].filter_vsp = x265_interp_4tap_vert_sp_4x4_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_4x4].filter_vss = x265_interp_4tap_vert_ss_4x4_avx2;
+ p.chroma[X265_CSP_I420].pu[CHROMA_420_4x8].filter_vpp = x265_interp_4tap_vert_pp_4x8_avx2;
+ p.chroma[X265_CSP_I420].pu[CHROMA_420_4x8].filter_vps = x265_interp_4tap_vert_ps_4x8_avx2;
+ p.chroma[X265_CSP_I420].pu[CHROMA_420_4x8].filter_vsp = x265_interp_4tap_vert_sp_4x8_avx2;
+ p.chroma[X265_CSP_I420].pu[CHROMA_420_4x8].filter_vss = x265_interp_4tap_vert_ss_4x8_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_8x2].filter_vpp = x265_interp_4tap_vert_pp_8x2_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_8x2].filter_vps = x265_interp_4tap_vert_ps_8x2_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_8x2].filter_vsp = x265_interp_4tap_vert_sp_8x2_avx2;
diff -r 64fcb3fcde5a -r d4cd5ae54e4b source/common/x86/ipfilter16.asm
--- a/source/common/x86/ipfilter16.asm Thu Jun 11 11:59:05 2015 +0530
+++ b/source/common/x86/ipfilter16.asm Thu Jun 11 12:25:56 2015 +0530
@@ -11820,3 +11820,116 @@
FILTER_VER_CHROMA_AVX2_4x4 ps, 0, 2
FILTER_VER_CHROMA_AVX2_4x4 sp, 1, 10
FILTER_VER_CHROMA_AVX2_4x4 ss, 0, 6
+
+
+%macro FILTER_VER_CHROMA_AVX2_4x8 3
+INIT_YMM avx2
+cglobal interp_4tap_vert_%1_4x8, 4, 7, 8
+ mov r4d, r4m
+ shl r4d, 6
+ add r1d, r1d
+ add r3d, r3d
+
+%ifdef PIC
+ lea r5, [tab_ChromaCoeffVer]
+ add r5, r4
+%else
+ lea r5, [tab_ChromaCoeffVer + r4]
+%endif
+
+ lea r4, [r1 * 3]
+ sub r0, r1
+
+%ifidn %1,pp
+ vbroadcasti128 m7, [pd_32]
+%elifidn %1, sp
+ mova m7, [pd_524800]
+%else
+ vbroadcasti128 m7, [pd_n32768]
+%endif
+ lea r6, [r3 * 3]
+
+ movq xm0, [r0] ; row 0
+ movq xm1, [r0 + r1] ; row 1
+ punpcklwd xm0, xm1
+ movq xm2, [r0 + r1 * 2] ; row 2
+ punpcklwd xm1, xm2
+ vinserti128 m0, m0, xm1, 1 ; m0 = [2 1 1 0]
+ pmaddwd m0, [r5]
+
+ movq xm3, [r0 + r4] ; row 3
+ punpcklwd xm2, xm3
+ lea r0, [r0 + 4 * r1]
+ movq xm4, [r0] ; row 4
+ punpcklwd xm3, xm4
+ vinserti128 m2, m2, xm3, 1 ; m2 = [4 3 3 2]
+ pmaddwd m5, m2, [r5 + 1 * mmsize]
+ pmaddwd m2, [r5]
+ paddd m0, m5
+
+ movq xm3, [r0 + r1] ; row 5
+ punpcklwd xm4, xm3
+ movq xm1, [r0 + r1 * 2] ; row 6
+ punpcklwd xm3, xm1
+ vinserti128 m4, m4, xm3, 1 ; m4 = [6 5 5 4]
+ pmaddwd m5, m4, [r5 + 1 * mmsize]
+ paddd m2, m5
+ pmaddwd m4, [r5]
+
+ movq xm3, [r0 + r4] ; row 7
+ punpcklwd xm1, xm3
+ lea r0, [r0 + 4 * r1]
+ movq xm6, [r0] ; row 8
+ punpcklwd xm3, xm6
+ vinserti128 m1, m1, xm3, 1 ; m1 = [8 7 7 6]
+ pmaddwd m5, m1, [r5 + 1 * mmsize]
+ paddd m4, m5
+ pmaddwd m1, [r5]
+
+ movq xm3, [r0 + r1] ; row 9
+ punpcklwd xm6, xm3
+ movq xm5, [r0 + 2 * r1] ; row 10
+ punpcklwd xm3, xm5
+ vinserti128 m6, m6, xm3, 1 ; m6 = [A 9 9 8]
+ pmaddwd m6, [r5 + 1 * mmsize]
+ paddd m1, m6
+%ifnidn %1,ss
+ paddd m0, m7
+ paddd m2, m7
+%endif
+ psrad m0, %3
+ psrad m2, %3
+ packssdw m0, m2
+ pxor m6, m6
+ mova m3, [pw_pixel_max]
+%if %2
+ CLIPW m0, m6, m3
+%endif
+ vextracti128 xm2, m0, 1
+ movq [r2], xm0
+ movq [r2 + r3], xm2
+ movhps [r2 + r3 * 2], xm0
+ movhps [r2 + r6], xm2
+%ifnidn %1,ss
+ paddd m4, m7
+ paddd m1, m7
+%endif
+ psrad m4, %3
+ psrad m1, %3
+ packssdw m4, m1
+%if %2
+ CLIPW m4, m6, m3
+%endif
+ vextracti128 xm1, m4, 1
+ lea r2, [r2 + r3 * 4]
+ movq [r2], xm4
+ movq [r2 + r3], xm1
+ movhps [r2 + r3 * 2], xm4
+ movhps [r2 + r6], xm1
+ RET
+%endmacro
+
+FILTER_VER_CHROMA_AVX2_4x8 pp, 1, 6
+FILTER_VER_CHROMA_AVX2_4x8 ps, 0, 2
+FILTER_VER_CHROMA_AVX2_4x8 sp, 1, 10
+FILTER_VER_CHROMA_AVX2_4x8 ss, 0 , 6
More information about the x265-devel
mailing list