[x265] [PATCH 4 of 6] asm: 10bpp avx2 code for intra_pred_ang32x32 mode 16 & 20
dnyaneshwar at multicorewareinc.com
dnyaneshwar at multicorewareinc.com
Tue Jun 16 12:34:50 CEST 2015
# HG changeset patch
# User Dnyaneshwar G <dnyaneshwar at multicorewareinc.com>
# Date 1434450593 -19800
# Tue Jun 16 15:59:53 2015 +0530
# Node ID 0501b1c89275c12eb3aa39e2ae300c6ee337a7f0
# Parent 3a4442aa079729f676f3e830d225ec4895772dda
asm: 10bpp avx2 code for intra_pred_ang32x32 mode 16 & 20
performance improvement over SSE:
intra_ang_32x32[16] 8032c->4841c, 40%
intra_ang_32x32[20] 6171c->3277c, 47%
diff -r 3a4442aa0797 -r 0501b1c89275 source/common/x86/asm-primitives.cpp
--- a/source/common/x86/asm-primitives.cpp Tue Jun 16 15:58:50 2015 +0530
+++ b/source/common/x86/asm-primitives.cpp Tue Jun 16 15:59:53 2015 +0530
@@ -1324,6 +1324,8 @@
p.cu[BLOCK_32x32].intra_pred[13] = x265_intra_pred_ang32_13_avx2;
p.cu[BLOCK_32x32].intra_pred[14] = x265_intra_pred_ang32_14_avx2;
p.cu[BLOCK_32x32].intra_pred[15] = x265_intra_pred_ang32_15_avx2;
+ p.cu[BLOCK_32x32].intra_pred[16] = x265_intra_pred_ang32_16_avx2;
+ p.cu[BLOCK_32x32].intra_pred[20] = x265_intra_pred_ang32_20_avx2;
p.cu[BLOCK_32x32].intra_pred[21] = x265_intra_pred_ang32_21_avx2;
p.cu[BLOCK_32x32].intra_pred[22] = x265_intra_pred_ang32_22_avx2;
p.cu[BLOCK_32x32].intra_pred[23] = x265_intra_pred_ang32_23_avx2;
diff -r 3a4442aa0797 -r 0501b1c89275 source/common/x86/intrapred16.asm
--- a/source/common/x86/intrapred16.asm Tue Jun 16 15:58:50 2015 +0530
+++ b/source/common/x86/intrapred16.asm Tue Jun 16 15:59:53 2015 +0530
@@ -52,6 +52,7 @@
const pw_ang32_13_23, db 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 14, 15, 6, 7, 0, 1
const pw_ang32_14_22, db 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 10, 11, 6, 7, 0, 1
const pw_ang32_15_21, db 0, 0, 0, 0, 0, 0, 0, 0, 12, 13, 8, 9, 4, 5, 0, 1
+const pw_ang32_16_20, db 0, 0, 0, 0, 0, 0, 0, 0, 8, 9, 6, 7, 2, 3, 0, 1
const shuf_mode_13_23, db 0, 0, 14, 15, 6, 7, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0
const shuf_mode_14_22, db 14, 15, 10, 11, 4, 5, 0, 1, 0, 0, 0, 0, 0, 0, 0, 0
@@ -16460,6 +16461,466 @@
mov rsp, [rsp+4*mmsize]
RET
+
+;; angle 32, modes 16 and 20, row 0 to 15
+cglobal ang32_mode_16_20_rows_0_15
+ test r6d, r6d
+
+ movu m0, [r2 - 20]
+ movu m1, [r2 - 18]
+
+ punpcklwd m3, m0, m1
+ punpckhwd m0, m1
+
+ movu m1, [r2 - 4] ; [ 3 2 0 -1 -2 -3 -4 -5 -6 -7 -8 -9 -10 -11 -12 -13]
+ movu m4, [r2 - 2] ; [ 2 0 -1 -2 -3 -4 -5 -6 -7 -8 -9 -10 -11 -12 -13 -14]
+ punpcklwd m2, m1, m4 ; [-3 -2 -4 -3 -5 -4 -6 -5 -11 -10 -12 -11 -13 -12 -14 -13]
+ punpckhwd m1, m4 ; [ 2 3 2 0 -1 0 -2 -1 -7 -6 -8 -7 -9 -8 -10 -9]
+
+ pmaddwd m4, m3, [r3] ; [16]
+ paddd m4, [pd_16]
+ psrld m4, 5
+ pmaddwd m5, m0, [r3]
+ paddd m5, [pd_16]
+ psrld m5, 5
+ packusdw m4, m5
+
+ palignr m6, m0, m3, 4
+ palignr m7, m2, m0, 4
+ pmaddwd m5, m6, [r3 - 11 * 32] ; [5]
+ paddd m5, [pd_16]
+ psrld m5, 5
+ pmaddwd m8, m7, [r3 - 11 * 32]
+ paddd m8, [pd_16]
+ psrld m8, 5
+ packusdw m5, m8
+
+ pmaddwd m6, [r3 + 10 * 32] ; [26]
+ paddd m6, [pd_16]
+ psrld m6, 5
+ pmaddwd m7, [r3 + 10 * 32]
+ paddd m7, [pd_16]
+ psrld m7, 5
+ packusdw m6, m7
+
+ palignr m8, m0, m3, 8
+ palignr m9, m2, m0, 8
+ pmaddwd m7, m8, [r3 - 1 * 32] ; [15]
+ paddd m7, [pd_16]
+ psrld m7, 5
+ pmaddwd m10, m9, [r3 - 1 * 32]
+ paddd m10, [pd_16]
+ psrld m10, 5
+ packusdw m7, m10
+
+ palignr m9, m0, m3, 12
+ palignr m12, m2, m0, 12
+ pmaddwd m8, m9, [r3 - 12 * 32] ; [4]
+ paddd m8, [pd_16]
+ psrld m8, 5
+ pmaddwd m10, m12, [r3 - 12 * 32]
+ paddd m10, [pd_16]
+ psrld m10, 5
+ packusdw m8, m10
+
+ pmaddwd m9, [r3 + 9 * 32] ; [25]
+ paddd m9, [pd_16]
+ psrld m9, 5
+ pmaddwd m12, [r3 + 9 * 32]
+ paddd m12, [pd_16]
+ psrld m12, 5
+ packusdw m9, m12
+
+ pmaddwd m10, m0, [r3 - 2 * 32] ; [14]
+ paddd m10, [pd_16]
+ psrld m10, 5
+ pmaddwd m11, m2, [r3 - 2 * 32]
+ paddd m11, [pd_16]
+ psrld m11, 5
+ packusdw m10, m11
+
+ palignr m11, m2, m0, 4
+ palignr m12, m1, m2, 4
+ pmaddwd m11, [r3 - 13 * 32] ; [3]
+ paddd m11, [pd_16]
+ psrld m11, 5
+ pmaddwd m12, [r3 - 13 * 32]
+ paddd m12, [pd_16]
+ psrld m12, 5
+ packusdw m11, m12
+
+ TRANSPOSE_STORE_AVX2_STACK 11, 10, 9, 8, 7, 6, 5, 4, 12, 13, 16
+
+ palignr m4, m2, m0, 4
+ palignr m5, m1, m2, 4
+ pmaddwd m4, [r3 + 8 * 32] ; [24]
+ paddd m4, [pd_16]
+ psrld m4, 5
+ pmaddwd m5, [r3 + 8 * 32]
+ paddd m5, [pd_16]
+ psrld m5, 5
+ packusdw m4, m5
+
+ palignr m5, m2, m0, 8
+ palignr m3, m1, m2, 8
+ pmaddwd m5, [r3 - 3 * 32] ; [13]
+ paddd m5, [pd_16]
+ psrld m5, 5
+ pmaddwd m3, [r3 - 3 * 32]
+ paddd m3, [pd_16]
+ psrld m3, 5
+ packusdw m5, m3
+
+ palignr m7, m2, m0, 12
+ palignr m3, m1, m2, 12
+ pmaddwd m6, m7, [r3 - 14 * 32] ; [2]
+ paddd m6, [pd_16]
+ psrld m6, 5
+ pmaddwd m8, m3, [r3 - 14 * 32]
+ paddd m8, [pd_16]
+ psrld m8, 5
+ packusdw m6, m8
+
+ pmaddwd m7, [r3 + 7 * 32] ; [23]
+ paddd m7, [pd_16]
+ psrld m7, 5
+ pmaddwd m3, [r3 + 7 * 32]
+ paddd m3, [pd_16]
+ psrld m3, 5
+ packusdw m7, m3
+
+ pmaddwd m8, m2, [r3 - 4 * 32] ; [12]
+ paddd m8, [pd_16]
+ psrld m8, 5
+ pmaddwd m9, m1, [r3 - 4 * 32]
+ paddd m9, [pd_16]
+ psrld m9, 5
+ packusdw m8, m9
+
+ movu m0, [r2 - 2]
+ movu m1, [r2]
+
+ punpcklwd m3, m0, m1
+ punpckhwd m0, m1
+
+ movu m2, [r2 + 14]
+ movu m1, [r2 + 16]
+ punpcklwd m2, m1
+
+ pmaddwd m9, m3, [r3 - 15 * 32] ; [1]
+ paddd m9, [pd_16]
+ psrld m9, 5
+ pmaddwd m10, m0, [r3 - 15 * 32]
+ paddd m10, [pd_16]
+ psrld m10, 5
+ packusdw m9, m10
+
+ pmaddwd m10, m3, [r3 + 6 * 32] ; [22]
+ paddd m10, [pd_16]
+ psrld m10, 5
+ pmaddwd m11, m0, [r3 + 6 * 32]
+ paddd m11, [pd_16]
+ psrld m11, 5
+ packusdw m10, m11
+
+ palignr m2, m0, 4
+ palignr m0, m3, 4
+ pmaddwd m0, [r3 - 5 * 32] ; [11]
+ paddd m0, [pd_16]
+ psrld m0, 5
+ pmaddwd m2, [r3 - 5 * 32]
+ paddd m2, [pd_16]
+ psrld m2, 5
+ packusdw m0, m2
+ TRANSPOSE_STORE_AVX2_STACK 0, 10, 9, 8, 7, 6, 5, 4, 2, 1, 0
+ ret
+
+;; angle 32, modes 16 and 20, rows 16 to 31
+cglobal ang32_mode_16_20_rows_16_31
+ test r6d, r6d
+
+ movu m0, [r2 - 40]
+ movu m1, [r2 - 38]
+
+ punpcklwd m3, m0, m1
+ punpckhwd m0, m1
+
+ movu m1, [r2 - 24]
+ movu m4, [r2 - 22]
+ punpcklwd m2, m1, m4
+ punpckhwd m1, m4
+
+ pmaddwd m4, m3, [r3 - 16 * 32] ; [0]
+ paddd m4, [pd_16]
+ psrld m4, 5
+ pmaddwd m5, m0, [r3 - 16 * 32]
+ paddd m5, [pd_16]
+ psrld m5, 5
+ packusdw m4, m5
+
+ pmaddwd m5, m3, [r3 + 5 * 32] ; [21]
+ paddd m5, [pd_16]
+ psrld m5, 5
+ pmaddwd m8, m0, [r3 + 5 * 32]
+ paddd m8, [pd_16]
+ psrld m8, 5
+ packusdw m5, m8
+
+ palignr m7, m0, m3, 4
+ palignr m8, m2, m0, 4
+ pmaddwd m6, m7, [r3 - 6 * 32] ; [10]
+ paddd m6, [pd_16]
+ psrld m6, 5
+ pmaddwd m9, m8, [r3 - 6 * 32]
+ paddd m9, [pd_16]
+ psrld m9, 5
+ packusdw m6, m9
+
+ pmaddwd m7, [r3 + 15 * 32] ; [31]
+ paddd m7, [pd_16]
+ psrld m7, 5
+ pmaddwd m8, [r3 + 15 * 32]
+ paddd m8, [pd_16]
+ psrld m8, 5
+ packusdw m7, m8
+
+ palignr m8, m0, m3, 8
+ palignr m9, m2, m0, 8
+ pmaddwd m8, [r3 + 4 * 32] ; [20]
+ paddd m8, [pd_16]
+ psrld m8, 5
+ pmaddwd m9, [r3 + 4 * 32]
+ paddd m9, [pd_16]
+ psrld m9, 5
+ packusdw m8, m9
+
+ palignr m10, m0, m3, 12
+ palignr m11, m2, m0, 12
+ pmaddwd m9, m10, [r3 - 7 * 32] ; [9]
+ paddd m9, [pd_16]
+ psrld m9, 5
+ pmaddwd m12, m11, [r3 - 7 * 32]
+ paddd m12, [pd_16]
+ psrld m12, 5
+ packusdw m9, m12
+
+ pmaddwd m10, [r3 + 14 * 32] ; [30]
+ paddd m10, [pd_16]
+ psrld m10, 5
+ pmaddwd m11, [r3 + 14 * 32]
+ paddd m11, [pd_16]
+ psrld m11, 5
+ packusdw m10, m11
+
+ pmaddwd m11, m0, [r3 + 3 * 32] ; [19]
+ paddd m11, [pd_16]
+ psrld m11, 5
+ pmaddwd m12, m2, [r3 + 3 * 32]
+ paddd m12, [pd_16]
+ psrld m12, 5
+ packusdw m11, m12
+
+ TRANSPOSE_STORE_AVX2_STACK 11, 10, 9, 8, 7, 6, 5, 4, 12, 13, 16
+
+ palignr m5, m2, m0, 4
+ palignr m6, m1, m2, 4
+ pmaddwd m4, m5, [r3 - 8 * 32] ; [8]
+ paddd m4, [pd_16]
+ psrld m4, 5
+ pmaddwd m7, m6, [r3 - 8 * 32]
+ paddd m7, [pd_16]
+ psrld m7, 5
+ packusdw m4, m7
+
+ pmaddwd m5, [r3 + 13 * 32] ; [29]
+ paddd m5, [pd_16]
+ psrld m5, 5
+ pmaddwd m6, [r3 + 13 * 32]
+ paddd m6, [pd_16]
+ psrld m6, 5
+ packusdw m5, m6
+
+ palignr m6, m2, m0, 8
+ palignr m3, m1, m2, 8
+ pmaddwd m6, [r3 + 2 * 32] ; [18]
+ paddd m6, [pd_16]
+ psrld m6, 5
+ pmaddwd m3, [r3 + 2 * 32]
+ paddd m3, [pd_16]
+ psrld m3, 5
+ packusdw m6, m3
+
+ palignr m8, m2, m0, 12
+ palignr m9, m1, m2, 12
+ pmaddwd m7, m8, [r3 - 9 * 32] ; [7]
+ paddd m7, [pd_16]
+ psrld m7, 5
+ pmaddwd m10, m9, [r3 - 9 * 32]
+ paddd m10, [pd_16]
+ psrld m10, 5
+ packusdw m7, m10
+
+ pmaddwd m8, [r3 + 12 * 32] ; [28]
+ paddd m8, [pd_16]
+ psrld m8, 5
+ pmaddwd m9, [r3 + 12 * 32]
+ paddd m9, [pd_16]
+ psrld m9, 5
+ packusdw m8, m9
+
+ pmaddwd m9, m2, [r3 + 1 * 32] ; [17]
+ paddd m9, [pd_16]
+ psrld m9, 5
+ pmaddwd m3, m1, [r3 + 1 * 32]
+ paddd m3, [pd_16]
+ psrld m3, 5
+ packusdw m9, m3
+
+ movu m0, [r2 - 22]
+ movu m1, [r2 - 20]
+ punpcklwd m3, m0, m1
+ punpckhwd m0, m1
+
+ pmaddwd m10, m3, [r3 - 10 * 32] ; [6]
+ paddd m10, [pd_16]
+ psrld m10, 5
+ pmaddwd m11, m0, [r3 - 10 * 32]
+ paddd m11, [pd_16]
+ psrld m11, 5
+ packusdw m10, m11
+
+ pmaddwd m3, [r3 + 11 * 32] ; [27]
+ paddd m3, [pd_16]
+ psrld m3, 5
+ pmaddwd m0, [r3 + 11 * 32]
+ paddd m0, [pd_16]
+ psrld m0, 5
+ packusdw m3, m0
+ TRANSPOSE_STORE_AVX2_STACK 3, 10, 9, 8, 7, 6, 5, 4, 0, 1, 0
+ ret
+
+cglobal intra_pred_ang32_16, 3,8,14
+ mov r6, rsp
+ sub rsp, 5*mmsize+gprsize
+ and rsp, ~63
+ mov [rsp+5*mmsize], r6
+
+ movu m0, [r2 + 128]
+ movu m1, [r2 + 160]
+ movd xm2, [r2 + 192]
+
+ mova [rsp + 2*mmsize], m0
+ mova [rsp + 3*mmsize], m1
+ movd [rsp + 4*mmsize], xm2
+
+ add r1d, r1d
+ lea r4, [r1 * 3]
+ lea r3, [ang_table_avx2 + 16 * 32]
+
+ movu xm1, [r2 + 4]
+ movu xm2, [r2 + 16]
+ movu xm3, [r2 + 28]
+ movu xm4, [r2 + 40]
+ movu xm5, [r2 + 52]
+ pshufb xm1, [pw_ang32_16_20]
+ pshufb xm2, [pw_ang32_16_20]
+ pshufb xm3, [pw_ang32_16_20]
+ pshufb xm4, [pw_ang32_16_20]
+ pshufb xm5, [pw_ang32_16_20]
+
+ punpckhqdq xm2, xm1
+ punpckhqdq xm4, xm3
+ punpckhqdq xm5, xm5
+
+ movzx r6d, word [r2]
+ mov [rsp + 2*mmsize], r6w
+ movu [rsp + 48], xm2
+ movu [rsp + 32], xm4
+ movq [rsp + 24], xm5
+
+ xor r6d, r6d
+ lea r2, [rsp + 2*mmsize]
+ lea r7, [r0 + 8 * r1]
+
+ call ang32_mode_16_20_rows_0_15
+
+ lea r0, [r0 + 32]
+
+ call ang32_mode_16_20_rows_16_31
+
+ add r2, 32
+ lea r0, [r7 + 8 * r1]
+
+ call ang32_mode_16_20_rows_0_15
+
+ lea r0, [r0 + 32]
+
+ call ang32_mode_16_20_rows_16_31
+
+ mov rsp, [rsp+5*mmsize]
+ RET
+
+cglobal intra_pred_ang32_20, 3,8,14
+ mov r6, rsp
+ sub rsp, 5*mmsize+gprsize
+ and rsp, ~63
+ mov [rsp+5*mmsize], r6
+
+ movu m0, [r2]
+ movu m1, [r2 + 32]
+ movd xm2, [r2 + 64]
+
+ mova [rsp + 2*mmsize], m0
+ mova [rsp + 3*mmsize], m1
+ movd [rsp + 4*mmsize], xm2
+
+ add r1d, r1d
+ lea r4, [r1 * 3]
+ lea r3, [ang_table_avx2 + 16 * 32]
+
+ movu xm1, [r2 + 132]
+ movu xm2, [r2 + 144]
+ movu xm3, [r2 + 156]
+ movu xm4, [r2 + 168]
+ movu xm5, [r2 + 180]
+ pshufb xm1, [pw_ang32_16_20]
+ pshufb xm2, [pw_ang32_16_20]
+ pshufb xm3, [pw_ang32_16_20]
+ pshufb xm4, [pw_ang32_16_20]
+ pshufb xm5, [pw_ang32_16_20]
+
+ punpckhqdq xm2, xm1
+ punpckhqdq xm4, xm3
+ punpckhqdq xm5, xm5
+
+ movu [rsp + 48], xm2
+ movu [rsp + 32], xm4
+ movq [rsp + 24], xm5
+
+ xor r6d, r6d
+ inc r6d
+ lea r2, [rsp + 2*mmsize]
+ lea r5, [r0 + 32]
+
+ call ang32_mode_16_20_rows_0_15
+
+ lea r0, [r0 + 8 * r1]
+ lea r0, [r0 + 8 * r1]
+
+ call ang32_mode_16_20_rows_16_31
+
+ add r2, 32
+ mov r0, r5
+
+ call ang32_mode_16_20_rows_0_15
+
+ lea r0, [r0 + 8 * r1]
+ lea r0, [r0 + 8 * r1]
+
+ call ang32_mode_16_20_rows_16_31
+
+ mov rsp, [rsp+5*mmsize]
+ RET
;-------------------------------------------------------------------------------------------------------
; end of avx2 code for intra_pred_ang32 mode 2 to 34
;-------------------------------------------------------------------------------------------------------
More information about the x265-devel
mailing list