[x265] [PATCH Review Only] luma_hps[32x8, 32x16, 32x24, 32x32, 32x64] avx2 asm : improved 6058c->3579c, 9208c->5449c, 12504c->7155c, 15974c->9537c, 28644c->16476c
chen
chenm003 at 163.com
Tue Mar 3 16:20:35 CET 2015
- Previous message: [x265] [PATCH Review Only] luma_hps[32x8, 32x16, 32x24, 32x32, 32x64] avx2 asm : improved 6058c->3579c, 9208c->5449c, 12504c->7155c, 15974c->9537c, 28644c->16476c
- Next message: [x265] [PATCH Review Only] luma_hps[64x16, 64x32, 64x48, 64x64] avx2 asm: improved 17472c->10503c, 31107c->18187c, 44869c->26601c, 60809c->33937c
- Messages sorted by:
[ date ]
[ thread ]
[ subject ]
[ author ]
updated
At 2015-03-03 13:24:46,aasaipriya at multicorewareinc.com wrote:
># HG changeset patch
># User Aasaipriya Chandran <aasaipriya at multicorewareinc.com>
># Date 1425360254 -19800
># Tue Mar 03 10:54:14 2015 +0530
># Node ID 88824fdb34aefbe9fec3c1da8d30375e00fe7d14
># Parent 04861917b7b343216ac1b9a9f70e38396af53275
>luma_hps[32x8, 32x16, 32x24, 32x32, 32x64] avx2 asm : improved 6058c->3579c, 9208c->5449c, 12504c->7155c, 15974c->9537c, 28644c->16476c
>
>diff -r 04861917b7b3 -r 88824fdb34ae source/common/x86/asm-primitives.cpp
>--- a/source/common/x86/asm-primitives.cpp Thu Feb 26 19:11:18 2015 +0530
>+++ b/source/common/x86/asm-primitives.cpp Tue Mar 03 10:54:14 2015 +0530
>@@ -1786,6 +1786,12 @@
>
> p.pu[LUMA_48x64].luma_hpp = x265_interp_8tap_horiz_pp_48x64_avx2;
>
>+ p.pu[LUMA_32x32].luma_hps = x265_interp_8tap_horiz_ps_32x32_avx2;
>+ p.pu[LUMA_32x16].luma_hps = x265_interp_8tap_horiz_ps_32x16_avx2;
>+ p.pu[LUMA_32x24].luma_hps = x265_interp_8tap_horiz_ps_32x24_avx2;
>+ p.pu[LUMA_32x8].luma_hps = x265_interp_8tap_horiz_ps_32x8_avx2;
>+ p.pu[LUMA_32x64].luma_hps = x265_interp_8tap_horiz_ps_32x64_avx2;
>+
> p.chroma[X265_CSP_I420].pu[CHROMA_420_8x8].filter_hpp = x265_interp_4tap_horiz_pp_8x8_avx2;
> p.chroma[X265_CSP_I420].pu[CHROMA_420_4x4].filter_hpp = x265_interp_4tap_horiz_pp_4x4_avx2;
> p.chroma[X265_CSP_I420].pu[CHROMA_420_32x32].filter_hpp = x265_interp_4tap_horiz_pp_32x32_avx2;
>diff -r 04861917b7b3 -r 88824fdb34ae source/common/x86/ipfilter8.asm
>--- a/source/common/x86/ipfilter8.asm Thu Feb 26 19:11:18 2015 +0530
>+++ b/source/common/x86/ipfilter8.asm Tue Mar 03 10:54:14 2015 +0530
>@@ -1994,6 +1994,92 @@
> IPFILTER_LUMA_PS_16x_AVX2 16 , 32
> IPFILTER_LUMA_PS_16x_AVX2 16 , 64
>
>+%macro IPFILTER_LUMA_PS_32x_AVX2 2
>+INIT_YMM avx2
>+cglobal interp_8tap_horiz_ps_%1x%2, 6, 7, 8
>+%ifdef PIC
>+ lea r6, [tab_LumaCoeff]
>+ vpbroadcastq m0, [r6 + r4 * 8]
>+%else
>+ vpbroadcastq m0, [tab_LumaCoeff + r4 * 8]
>+%endif
>+ mova m6, [tab_Lm + 32]
>+ mova m1, [tab_Lm]
>+ mov r4, %2 ;height
>+ add r3d, r3d
>+ vbroadcasti128 m2, [pw_2000]
>+ mova m7, [interp8_hps_shuf]
>+ ; register map
>+ ; m0 - interpolate coeff
>+ ; m1 , m6 - shuffle order table
>+ ; m2 - pw_2000
>+
>+ sub r0, 3
>+ test r5d, r5d
>+ jz .label
>+ lea r6, [r1 * 3] ; r8 = (N / 2 - 1) * srcStride
>+ sub r0, r6
>+ ;sub r0, [r1 * 3] ; r0(src)-[r1*3]
>+ add r4, 7 ; blkheight += N - 1 (7 - 1 = 6 ; since the last one row not in loop)
>+
>+.label
use .loop is better
>+ ; Row 0
>+ vbroadcasti128 m3, [r0] ; [x x x x x A 9 8 7 6 5 4 3 2 1 0]
>+ pshufb m4, m3, m6 ; row 0 (col 4 to 7)
>+ pshufb m3, m1 ; shuffled based on the col order tab_Lm row 0 (col 0 to 3)
>+ pmaddubsw m3, m0
>+ pmaddubsw m4, m0
>+ phaddw m3, m4 ; DWORD [R1D R1C R0D R0C R1B R1A R0B R0A]
PMADDWD is faster here
>+
>+ vbroadcasti128 m4, [r0 + 8]
>+ pshufb m5, m4, m6 ;row 0 (col 12 to 15)
>+ pshufb m4, m1 ;row 0 (col 8 to 11)
>+ pmaddubsw m4, m0
>+ pmaddubsw m5, m0
>+ phaddw m4, m5 ; DWORD [R3D R3C R2D R2C R3B R3A R2B R2A]
>+
>+ phaddw m3, m4 ; col 0 - 16
>+ mova m5, m7
>+ vpermd m3, m5, m3
>+ psubw m3, m2
>+
>+ movu [r2], m3 ;row 0
>+
>+ vbroadcasti128 m3, [r0 + 16]
>+ pshufb m4, m3, m6 ; row 0 (col 20 to 23)
>+ pshufb m3, m1 ; row 0 (col 16 to 19)
>+ pmaddubsw m3, m0
>+ pmaddubsw m4, m0
>+ phaddw m3, m4 ; DWORD [R1D R1C R0D R0C R1B R1A R0
>+
>+ vbroadcasti128 m4, [r0 + 24]
>+ pshufb m5, m4, m6 ;row 0 (col 28 to 31)
>+ pshufb m4, m1 ;row 0 (col 24 to 27)
>+ pmaddubsw m4, m0
>+ pmaddubsw m5, m0
>+ phaddw m4, m5 ; DWORD [R3D R3C R2D R2C R3B R3A R2B R2
>+
>+ phaddw m3, m4 ; all rows and col completed.
>+ mova m5, m7
>+ vpermd m3, m5, m3
>+ psubw m3, m2
>+
>+ movu [r2 + 32], m3 ;row 0
>+
>+ lea r0, [r0 + r1] ; first loop src ->5th row(i.e 4)
>+ lea r2, [r2 + r3] ; first loop dst ->5th row(i.e 4)
ADD is execute in port6, it is faster
>+ dec r4d
>+ jnz .label
>+
>+RET
>+%endmacro
>+
>+
>+IPFILTER_LUMA_PS_32x_AVX2 32 , 32
>+IPFILTER_LUMA_PS_32x_AVX2 32 , 16
>+IPFILTER_LUMA_PS_32x_AVX2 32 , 24
>+IPFILTER_LUMA_PS_32x_AVX2 32 , 8
>+IPFILTER_LUMA_PS_32x_AVX2 32 , 64
>
> ;--------------------------------------------------------------------------------------------------------------
> ; void interp_8tap_horiz_pp_%1x%2(pixel *src, intptr_t srcStride, pixel *dst, intptr_t dstStride, int coeffIdx)
>_______________________________________________
>x265-devel mailing list
>x265-devel at videolan.org
>https://mailman.videolan.org/listinfo/x265-devel
-------------- next part --------------
An HTML attachment was scrubbed...
URL: <http://mailman.videolan.org/pipermail/x265-devel/attachments/20150303/172b5787/attachment-0001.html>
- Previous message: [x265] [PATCH Review Only] luma_hps[32x8, 32x16, 32x24, 32x32, 32x64] avx2 asm : improved 6058c->3579c, 9208c->5449c, 12504c->7155c, 15974c->9537c, 28644c->16476c
- Next message: [x265] [PATCH Review Only] luma_hps[64x16, 64x32, 64x48, 64x64] avx2 asm: improved 17472c->10503c, 31107c->18187c, 44869c->26601c, 60809c->33937c
- Messages sorted by:
[ date ]
[ thread ]
[ subject ]
[ author ]
More information about the x265-devel
mailing list