[x265] [PATCH Review Only] chroma_hps[16x16]for i420 avx2 asm code: 1624c->1093c

[chen]

At 2015-03-06 16:19:54,aasaipriya at multicorewareinc.com wrote:
># HG changeset patch
># User Aasaipriya Chandran <aasaipriya at multicorewareinc.com>
># Date 1425629985 -19800
>#      Fri Mar 06 13:49:45 2015 +0530
># Node ID 52f29a8cdecf7a3b5930b640c2b507c4f11b017a
># Parent  29d4d0251f06777190867d9de35c43379a414342
>chroma_hps[16x16]for i420 avx2 asm code: 1624c->1093c
>
>diff -r 29d4d0251f06 -r 52f29a8cdecf source/common/x86/asm-primitives.cpp
>--- a/source/common/x86/asm-primitives.cpp	Fri Mar 06 13:46:52 2015 +0530
>+++ b/source/common/x86/asm-primitives.cpp	Fri Mar 06 13:49:45 2015 +0530
>@@ -1792,6 +1792,7 @@
>         p.chroma[X265_CSP_I420].pu[CHROMA_420_16x16].filter_hpp = x265_interp_4tap_horiz_pp_16x16_avx2;
> 
>         p.chroma[X265_CSP_I420].pu[CHROMA_420_4x4].filter_hps = x265_interp_4tap_horiz_ps_4x4_avx2;
>+        p.chroma[X265_CSP_I420].pu[CHROMA_420_16x16].filter_hps = x265_interp_4tap_horiz_ps_16x16_avx2;
> 
>         p.pu[LUMA_4x4].luma_vps = x265_interp_8tap_vert_ps_4x4_avx2;
> 
>diff -r 29d4d0251f06 -r 52f29a8cdecf source/common/x86/ipfilter8.asm
>--- a/source/common/x86/ipfilter8.asm	Fri Mar 06 13:46:52 2015 +0530
>+++ b/source/common/x86/ipfilter8.asm	Fri Mar 06 13:49:45 2015 +0530
>@@ -1806,6 +1806,61 @@
>     RET
> 
> 
>+;-----------------------------------------------------------------------------------------------------------------------------
>+; void interp_4tap_horiz_ps_16x16(pixel *src, intptr_t srcStride, int16_t *dst, intptr_t dstStride, int coeffIdx, int isRowExt)
>+;-----------------------------------------------------------------------------------------------------------------------------;
>+INIT_YMM avx2 
>+cglobal interp_4tap_horiz_ps_16x16, 4,7,5
>+    mov             r4d, r4m
>+    mov             r5d, r5m
>+    add             r3d, r3d
>+
>+%ifdef PIC
>+    lea               r6,           [tab_ChromaCoeff]
>+    vpbroadcastd      m0,           [r6 + r4 * 4]
>+%else
>+    vpbroadcastd      m0,           [tab_ChromaCoeff + r4 * 4]
>+%endif
>+
>+    vpbroadcastd      m2,           [pw_1]

vbroadcasti128?

>+    movu              m1,           [tab_Tm]
unaligned?

>+
>+    ; register map
>+    ; m0 - interpolate coeff
>+    ; m1 - shuffle order table
>+    ; m2 - constant word 1
>+    mov                r6d,         16
>+    dec                r0
>+    cmp                r5m,         byte 0
>+    je                 .label
>+    sub                r0 ,         r1
>+    add                r6d ,        3
>+
>+.label
.loop?

>+    ; Row 0
>+    vbroadcasti128    m3,           [r0]                        ; [x x x x x A 9 8 7 6 5 4 3 2 1 0]
>+    pshufb            m3,           m1
>+    pmaddubsw         m3,           m0
>+    pmaddwd           m3,           m2
>+
>+    ; Row 1
>+    vbroadcasti128    m4,           [r0 + 8]                      ; [x x x x x A 9 8 7 6 5 4 3 2 1 0]
>+    pshufb            m4,           m1
>+    pmaddubsw         m4,           m0
>+    pmaddwd           m4,           m2
>+
>+    packssdw          m3,           m4
>+    psubw             m3,           [pw_2000]
we have more free register, so buffer the constant since here is loop

>+
>+    vpermq            m3,           m3,          11011000b
>+    movu             [r2],         m3
>+
>+    lea               r2,           [r2 + r3]
>+    lea               r0,           [r0 + r1]
add?
>+    dec               r6d
>+    jnz                .label
>+   RET
>+
> ;-----------------------------------------------------------------------------------------------------------------------------
> ;void interp_horiz_ps_c(const pixel* src, intptr_t srcStride, int16_t* dst, intptr_t dstStride, int coeffIdx, int isRowExt)
> ;-----------------------------------------------------------------------------------------------------------------------------
>_______________________________________________
>x265-devel mailing list
>x265-devel at videolan.org
>https://mailman.videolan.org/listinfo/x265-devel
-------------- next part --------------
An HTML attachment was scrubbed...
URL: <http://mailman.videolan.org/pipermail/x265-devel/attachments/20150307/e472c00d/attachment.html>