[x265] [PATCH] asm: intra_pred_ang8_14

[praveen at multicorewareinc.com]

# HG changeset patch
# User Praveen Tiwari <praveen at multicorewareinc.com>
# Date 1425990471 -19800
# Node ID c5215ffa12fee77b89c98888edf9faa369bacd41
# Parent  62dcfcba14e59543f92752c8145c612e13af472f
asm: intra_pred_ang8_14

diff -r 62dcfcba14e5 -r c5215ffa12fe source/common/x86/asm-primitives.cpp
--- a/source/common/x86/asm-primitives.cpp	Tue Mar 10 17:45:53 2015 +0530
+++ b/source/common/x86/asm-primitives.cpp	Tue Mar 10 17:57:51 2015 +0530
@@ -1500,6 +1500,7 @@
         p.cu[BLOCK_8x8].intra_pred[12] = x265_intra_pred_ang8_12_avx2;
         p.cu[BLOCK_8x8].intra_pred[24] = x265_intra_pred_ang8_24_avx2;
         p.cu[BLOCK_8x8].intra_pred[22] = x265_intra_pred_ang8_22_avx2;
+        p.cu[BLOCK_8x8].intra_pred[14] = x265_intra_pred_ang8_14_avx2;
 
         // copy_sp primitives
         p.cu[BLOCK_16x16].copy_sp = x265_blockcopy_sp_16x16_avx2;
diff -r 62dcfcba14e5 -r c5215ffa12fe source/common/x86/intrapred.h
--- a/source/common/x86/intrapred.h	Tue Mar 10 17:45:53 2015 +0530
+++ b/source/common/x86/intrapred.h	Tue Mar 10 17:57:51 2015 +0530
@@ -183,6 +183,7 @@
 void x265_intra_pred_ang8_12_avx2(pixel* dst, intptr_t dstStride, const pixel* srcPix, int dirMode, int bFilter);
 void x265_intra_pred_ang8_24_avx2(pixel* dst, intptr_t dstStride, const pixel* srcPix, int dirMode, int bFilter);
 void x265_intra_pred_ang8_22_avx2(pixel* dst, intptr_t dstStride, const pixel* srcPix, int dirMode, int bFilter);
+void x265_intra_pred_ang8_14_avx2(pixel* dst, intptr_t dstStride, const pixel* srcPix, int dirMode, int bFilter);
 void x265_all_angs_pred_4x4_sse4(pixel *dest, pixel *refPix, pixel *filtPix, int bLuma);
 void x265_all_angs_pred_8x8_sse4(pixel *dest, pixel *refPix, pixel *filtPix, int bLuma);
 void x265_all_angs_pred_16x16_sse4(pixel *dest, pixel *refPix, pixel *filtPix, int bLuma);
diff -r 62dcfcba14e5 -r c5215ffa12fe source/common/x86/intrapred8.asm
--- a/source/common/x86/intrapred8.asm	Tue Mar 10 17:45:53 2015 +0530
+++ b/source/common/x86/intrapred8.asm	Tue Mar 10 17:57:51 2015 +0530
@@ -10511,3 +10511,70 @@
     movhps            [r0 + 2 * r1], xm4
     movhps            [r0 + r3], xm2
     RET
+
+INIT_YMM avx2
+cglobal intra_pred_ang8_14, 3, 5, 6
+    mova              m3, [pw_1024]
+    movu              xm1, [r2 + 16]
+    pinsrb            xm1, [r2], 0
+    pshufb            xm1, [intra_pred_shuff_0_8]
+    vinserti128       m0, m1, xm1, 1
+
+    ; Row [0, 1] 
+    lea               r4, [c_ang8_mode_22]
+    pmaddubsw         m1, m0, [r4]
+    pmulhrsw          m1, m3
+
+    ; Row [2, 3]
+    vextracti128      xm5, m0, 0
+    pslldq            xm5, 2
+    pinsrb            xm5, [r2 + 2], 0
+    pinsrb            xm5, [r2 + 0], 1
+    vinserti128       m0, m5, xm5, 1
+    pmaddubsw         m2, m0, [r4 + mmsize]
+    pmulhrsw          m2, m3
+
+    ; Row [4, 5]
+    vextracti128      xm5, m0, 0
+    pslldq            xm5, 2
+    pinsrb            xm5, [r2 + 5], 0
+    pinsrb            xm5, [r2 + 2], 1
+    vinserti128       m0, m5, xm5, 1
+    pmaddubsw         m4, m0, [r4 + 2 * mmsize]
+    pmulhrsw          m4, m3
+
+    ; Row [6, 7]
+    vextracti128      xm5, m0, 0
+    pslldq            xm5, 2
+    pinsrb            xm5, [r2 + 7], 0
+    pinsrb            xm5, [r2 + 5], 1
+    vinserti128       m0, m0, xm5, 1
+    pmaddubsw         m0, [r4 + 3 * mmsize]
+    pmulhrsw          m0, m3
+
+    packuswb          m1, m2
+    packuswb          m4, m0
+
+    vperm2i128        m2, m1, m4, 00100000b
+    vperm2i128        m1, m1, m4, 00110001b
+    punpcklbw         m4, m2, m1
+    punpckhbw         m2, m1
+    punpcklwd         m1, m4, m2
+    punpckhwd         m4, m2
+    mova              m0, [trans8_shuf]
+    vpermd            m1, m0, m1
+    vpermd            m4, m0, m4
+
+    lea               r3, [3 * r1]
+    movq              [r0], xm1
+    movhps            [r0 + r1], xm1
+    vextracti128      xm2, m1, 1
+    movq              [r0 + 2 * r1], xm2
+    movhps            [r0 + r3], xm2
+    lea               r0, [r0 + 4 * r1]
+    movq              [r0], xm4
+    movhps            [r0 + r1], xm4
+    vextracti128      xm2, m4, 1
+    movq              [r0 + 2 * r1], xm2
+    movhps            [r0 + r3], xm2
+    RET