[x265] [PATCH] asm: filter_vpp[16x32], filter_vps[16x32] in avx2: 1944c->1870c, 1907c->1628c
Divya Manivannan
divya at multicorewareinc.com
Wed Mar 11 09:15:02 CET 2015
# HG changeset patch
# User Divya Manivannan <divya at multicorewareinc.com>
# Date 1426061646 -19800
# Wed Mar 11 13:44:06 2015 +0530
# Node ID e90e9eeda28ece884b4189eedd48051d6dc0b44f
# Parent 97ff5bb38e91610bcbbef706850c777171563e8b
asm: filter_vpp[16x32], filter_vps[16x32] in avx2: 1944c->1870c, 1907c->1628c
diff -r 97ff5bb38e91 -r e90e9eeda28e source/common/x86/asm-primitives.cpp
--- a/source/common/x86/asm-primitives.cpp Wed Mar 11 12:00:17 2015 +0530
+++ b/source/common/x86/asm-primitives.cpp Wed Mar 11 13:44:06 2015 +0530
@@ -1594,6 +1594,7 @@
p.chroma[X265_CSP_I420].pu[CHROMA_420_16x4].filter_vpp = x265_interp_4tap_vert_pp_16x4_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_16x8].filter_vpp = x265_interp_4tap_vert_pp_16x8_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_16x16].filter_vpp = x265_interp_4tap_vert_pp_16x16_avx2;
+ p.chroma[X265_CSP_I420].pu[CHROMA_420_16x32].filter_vpp = x265_interp_4tap_vert_pp_16x32_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_32x8].filter_vpp = x265_interp_4tap_vert_pp_32x8_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_32x16].filter_vpp = x265_interp_4tap_vert_pp_32x16_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_32x24].filter_vpp = x265_interp_4tap_vert_pp_32x24_avx2;
@@ -1616,6 +1617,7 @@
p.chroma[X265_CSP_I420].pu[CHROMA_420_16x8].filter_vps = x265_interp_4tap_vert_ps_16x8_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_4x16].filter_vps = x265_interp_4tap_vert_ps_4x16_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_16x16].filter_vps = x265_interp_4tap_vert_ps_16x16_avx2;
+ p.chroma[X265_CSP_I420].pu[CHROMA_420_16x32].filter_vps = x265_interp_4tap_vert_ps_16x32_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_32x32].filter_vps = x265_interp_4tap_vert_ps_32x32_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_32x24].filter_vps = x265_interp_4tap_vert_ps_32x24_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_32x16].filter_vps = x265_interp_4tap_vert_ps_32x16_avx2;
diff -r 97ff5bb38e91 -r e90e9eeda28e source/common/x86/ipfilter8.asm
--- a/source/common/x86/ipfilter8.asm Wed Mar 11 12:00:17 2015 +0530
+++ b/source/common/x86/ipfilter8.asm Wed Mar 11 13:44:06 2015 +0530
@@ -5905,6 +5905,299 @@
FILTER_VER_CHROMA_AVX2_16x4 pp
FILTER_VER_CHROMA_AVX2_16x4 ps
+%macro FILTER_VER_CHROMA_AVX2_16x32 1
+INIT_YMM avx2
+%if ARCH_X86_64 == 1
+cglobal interp_4tap_vert_%1_16x32, 4, 8, 8
+ mov r4d, r4m
+ shl r4d, 6
+
+%ifdef PIC
+ lea r5, [tab_ChromaCoeffVer_32]
+ add r5, r4
+%else
+ lea r5, [tab_ChromaCoeffVer_32 + r4]
+%endif
+
+ lea r4, [r1 * 3]
+ sub r0, r1
+%ifidn %1,pp
+ mova m7, [pw_512]
+%else
+ add r3d, r3d
+ mova m7, [pw_2000]
+%endif
+ lea r6, [r3 * 3]
+ mov r7d, 2
+.loopH:
+ movu xm0, [r0]
+ vinserti128 m0, m0, [r0 + r1 * 2], 1
+ movu xm1, [r0 + r1]
+ vinserti128 m1, m1, [r0 + r4], 1
+
+ punpcklbw m2, m0, m1
+ punpckhbw m3, m0, m1
+ vperm2i128 m4, m2, m3, 0x20
+ vperm2i128 m2, m2, m3, 0x31
+ pmaddubsw m4, [r5]
+ pmaddubsw m3, m2, [r5 + mmsize]
+ paddw m4, m3
+ pmaddubsw m2, [r5]
+
+ vextracti128 xm0, m0, 1
+ lea r0, [r0 + r1 * 4]
+ vinserti128 m0, m0, [r0], 1
+
+ punpcklbw m5, m1, m0
+ punpckhbw m3, m1, m0
+ vperm2i128 m6, m5, m3, 0x20
+ vperm2i128 m5, m5, m3, 0x31
+ pmaddubsw m6, [r5]
+ pmaddubsw m3, m5, [r5 + mmsize]
+ paddw m6, m3
+ pmaddubsw m5, [r5]
+%ifidn %1,pp
+ pmulhrsw m4, m7 ; m4 = word: row 0
+ pmulhrsw m6, m7 ; m6 = word: row 1
+ packuswb m4, m6
+ vpermq m4, m4, 11011000b
+ vextracti128 xm6, m4, 1
+ movu [r2], xm4
+ movu [r2 + r3], xm6
+%else
+ psubw m4, m7 ; m4 = word: row 0
+ psubw m6, m7 ; m6 = word: row 1
+ movu [r2], m4
+ movu [r2 + r3], m6
+%endif
+
+ movu xm4, [r0 + r1 * 2]
+ vinserti128 m4, m4, [r0 + r1], 1
+ vextracti128 xm1, m4, 1
+ vinserti128 m0, m0, xm1, 0
+
+ punpcklbw m6, m0, m4
+ punpckhbw m1, m0, m4
+ vperm2i128 m0, m6, m1, 0x20
+ vperm2i128 m6, m6, m1, 0x31
+ pmaddubsw m1, m0, [r5 + mmsize]
+ paddw m5, m1
+ pmaddubsw m0, [r5]
+ pmaddubsw m1, m6, [r5 + mmsize]
+ paddw m2, m1
+ pmaddubsw m6, [r5]
+
+%ifidn %1,pp
+ pmulhrsw m2, m7 ; m2 = word: row 2
+ pmulhrsw m5, m7 ; m5 = word: row 3
+ packuswb m2, m5
+ vpermq m2, m2, 11011000b
+ vextracti128 xm5, m2, 1
+ movu [r2 + r3 * 2], xm2
+ movu [r2 + r6], xm5
+%else
+ psubw m2, m7 ; m2 = word: row 2
+ psubw m5, m7 ; m5 = word: row 3
+ movu [r2 + r3 * 2], m2
+ movu [r2 + r6], m5
+%endif
+ lea r2, [r2 + r3 * 4]
+
+ movu xm1, [r0 + r4]
+ lea r0, [r0 + r1 * 4]
+ vinserti128 m1, m1, [r0], 1
+ vinserti128 m4, m4, xm1, 1
+
+ punpcklbw m2, m4, m1
+ punpckhbw m5, m4, m1
+ vperm2i128 m3, m2, m5, 0x20
+ vperm2i128 m2, m2, m5, 0x31
+ pmaddubsw m5, m3, [r5 + mmsize]
+ paddw m6, m5
+ pmaddubsw m3, [r5]
+ pmaddubsw m5, m2, [r5 + mmsize]
+ paddw m0, m5
+ pmaddubsw m2, [r5]
+
+%ifidn %1,pp
+ pmulhrsw m6, m7 ; m6 = word: row 4
+ pmulhrsw m0, m7 ; m0 = word: row 5
+ packuswb m6, m0
+ vpermq m6, m6, 11011000b
+ vextracti128 xm0, m6, 1
+ movu [r2], xm6
+ movu [r2 + r3], xm0
+%else
+ psubw m6, m7 ; m6 = word: row 4
+ psubw m0, m7 ; m0 = word: row 5
+ movu [r2], m6
+ movu [r2 + r3], m0
+%endif
+
+ movu xm6, [r0 + r1 * 2]
+ vinserti128 m6, m6, [r0 + r1], 1
+ vextracti128 xm0, m6, 1
+ vinserti128 m1, m1, xm0, 0
+
+ punpcklbw m4, m1, m6
+ punpckhbw m5, m1, m6
+ vperm2i128 m0, m4, m5, 0x20
+ vperm2i128 m5, m4, m5, 0x31
+ pmaddubsw m4, m0, [r5 + mmsize]
+ paddw m2, m4
+ pmaddubsw m0, [r5]
+ pmaddubsw m4, m5, [r5 + mmsize]
+ paddw m3, m4
+ pmaddubsw m5, [r5]
+
+%ifidn %1,pp
+ pmulhrsw m3, m7 ; m3 = word: row 6
+ pmulhrsw m2, m7 ; m2 = word: row 7
+ packuswb m3, m2
+ vpermq m3, m3, 11011000b
+ vextracti128 xm2, m3, 1
+ movu [r2 + r3 * 2], xm3
+ movu [r2 + r6], xm2
+%else
+ psubw m3, m7 ; m3 = word: row 6
+ psubw m2, m7 ; m2 = word: row 7
+ movu [r2 + r3 * 2], m3
+ movu [r2 + r6], m2
+%endif
+ lea r2, [r2 + r3 * 4]
+
+ movu xm3, [r0 + r4]
+ lea r0, [r0 + r1 * 4]
+ vinserti128 m3, m3, [r0], 1
+ vinserti128 m6, m6, xm3, 1
+
+ punpcklbw m2, m6, m3
+ punpckhbw m1, m6, m3
+ vperm2i128 m4, m2, m1, 0x20
+ vperm2i128 m2, m2, m1, 0x31
+ pmaddubsw m1, m4, [r5 + mmsize]
+ paddw m5, m1
+ pmaddubsw m4, [r5]
+ pmaddubsw m1, m2, [r5 + mmsize]
+ paddw m0, m1
+ pmaddubsw m2, [r5]
+
+%ifidn %1,pp
+ pmulhrsw m5, m7 ; m5 = word: row 8
+ pmulhrsw m0, m7 ; m0 = word: row 9
+ packuswb m5, m0
+ vpermq m5, m5, 11011000b
+ vextracti128 xm0, m5, 1
+ movu [r2], xm5
+ movu [r2 + r3], xm0
+%else
+ psubw m5, m7 ; m5 = word: row 8
+ psubw m0, m7 ; m0 = word: row 9
+ movu [r2], m5
+ movu [r2 + r3], m0
+%endif
+
+ movu xm5, [r0 + r1 * 2]
+ vinserti128 m5, m5, [r0 + r1], 1
+ vextracti128 xm0, m5, 1
+ vinserti128 m3, m3, xm0, 0
+
+ punpcklbw m1, m3, m5
+ punpckhbw m0, m3, m5
+ vperm2i128 m6, m1, m0, 0x20
+ vperm2i128 m0, m1, m0, 0x31
+ pmaddubsw m1, m6, [r5 + mmsize]
+ paddw m2, m1
+ pmaddubsw m6, [r5]
+ pmaddubsw m1, m0, [r5 + mmsize]
+ paddw m4, m1
+ pmaddubsw m0, [r5]
+
+%ifidn %1,pp
+ pmulhrsw m4, m7 ; m4 = word: row 10
+ pmulhrsw m2, m7 ; m2 = word: row 11
+ packuswb m4, m2
+ vpermq m4, m4, 11011000b
+ vextracti128 xm2, m4, 1
+ movu [r2 + r3 * 2], xm4
+ movu [r2 + r6], xm2
+%else
+ psubw m4, m7 ; m4 = word: row 10
+ psubw m2, m7 ; m2 = word: row 11
+ movu [r2 + r3 * 2], m4
+ movu [r2 + r6], m2
+%endif
+ lea r2, [r2 + r3 * 4]
+
+ movu xm3, [r0 + r4]
+ lea r0, [r0 + r1 * 4]
+ vinserti128 m3, m3, [r0], 1
+ vinserti128 m5, m5, xm3, 1
+
+ punpcklbw m2, m5, m3
+ punpckhbw m1, m5, m3
+ vperm2i128 m4, m2, m1, 0x20
+ vperm2i128 m2, m2, m1, 0x31
+ pmaddubsw m1, m4, [r5 + mmsize]
+ paddw m0, m1
+ pmaddubsw m4, [r5]
+ pmaddubsw m1, m2, [r5 + mmsize]
+ paddw m6, m1
+ pmaddubsw m2, [r5]
+
+%ifidn %1,pp
+ pmulhrsw m0, m7 ; m0 = word: row 12
+ pmulhrsw m6, m7 ; m6 = word: row 13
+ packuswb m0, m6
+ vpermq m0, m0, 11011000b
+ vextracti128 xm6, m0, 1
+ movu [r2], xm0
+ movu [r2 + r3], xm6
+%else
+ psubw m0, m7 ; m0 = word: row 12
+ psubw m6, m7 ; m6 = word: row 13
+ movu [r2], m0
+ movu [r2 + r3], m6
+%endif
+
+ movu xm5, [r0 + r1 * 2]
+ vinserti128 m5, m5, [r0 + r1], 1
+ vextracti128 xm0, m5, 1
+ vinserti128 m3, m3, xm0, 0
+
+ punpcklbw m1, m3, m5
+ punpckhbw m0, m3, m5
+ vperm2i128 m6, m1, m0, 0x20
+ vperm2i128 m0, m1, m0, 0x31
+ pmaddubsw m6, [r5 + mmsize]
+ paddw m2, m6
+ pmaddubsw m0, [r5 + mmsize]
+ paddw m4, m0
+
+%ifidn %1,pp
+ pmulhrsw m4, m7 ; m4 = word: row 14
+ pmulhrsw m2, m7 ; m2 = word: row 15
+ packuswb m4, m2
+ vpermq m4, m4, 11011000b
+ vextracti128 xm2, m4, 1
+ movu [r2 + r3 * 2], xm4
+ movu [r2 + r6], xm2
+%else
+ psubw m4, m7 ; m4 = word: row 14
+ psubw m2, m7 ; m2 = word: row 15
+ movu [r2 + r3 * 2], m4
+ movu [r2 + r6], m2
+%endif
+ lea r2, [r2 + r3 * 4]
+ dec r7d
+ jnz .loopH
+ RET
+%endif
+%endmacro
+
+FILTER_VER_CHROMA_AVX2_16x32 pp
+FILTER_VER_CHROMA_AVX2_16x32 ps
+
;-----------------------------------------------------------------------------
;void interp_4tap_vert_pp_24x32(pixel *src, intptr_t srcStride, pixel *dst, intptr_t dstStride, int coeffIdx)
;-----------------------------------------------------------------------------
More information about the x265-devel
mailing list