[x265] [PATCH] asm : luma_hps[64x64 , 64x48 , 64x32 , 64x16] avx2 - improved 58533c->31129c, 43517c->22938c, 31254c->16714c, 17540c->9063c
aasaipriya at multicorewareinc.com
aasaipriya at multicorewareinc.com
Wed Mar 11 11:01:30 CET 2015
# HG changeset patch
# User Aasaipriya Chandran <aasaipriya at multicorewareinc.com>
# Date 1426068050 -19800
# Wed Mar 11 15:30:50 2015 +0530
# Node ID c076f0195a36f278f99967756426526816c18273
# Parent 57e51fa4dd246720cb4c3e12005e7682baf26e7f
asm : luma_hps[64x64 , 64x48 , 64x32 , 64x16] avx2 - improved 58533c->31129c, 43517c->22938c, 31254c->16714c, 17540c->9063c
diff -r 57e51fa4dd24 -r c076f0195a36 source/common/x86/asm-primitives.cpp
--- a/source/common/x86/asm-primitives.cpp Wed Mar 11 14:47:40 2015 +0530
+++ b/source/common/x86/asm-primitives.cpp Wed Mar 11 15:30:50 2015 +0530
@@ -1576,6 +1576,11 @@
p.pu[LUMA_32x8].luma_hps = x265_interp_8tap_horiz_ps_32x8_avx2;
p.pu[LUMA_32x64].luma_hps = x265_interp_8tap_horiz_ps_32x64_avx2;
+ p.pu[LUMA_64x64].luma_hps = x265_interp_8tap_horiz_ps_64x64_avx2;
+ p.pu[LUMA_64x48].luma_hps = x265_interp_8tap_horiz_ps_64x48_avx2;
+ p.pu[LUMA_64x32].luma_hps = x265_interp_8tap_horiz_ps_64x32_avx2;
+ p.pu[LUMA_64x16].luma_hps = x265_interp_8tap_horiz_ps_64x16_avx2;
+
p.chroma[X265_CSP_I420].pu[CHROMA_420_8x8].filter_hpp = x265_interp_4tap_horiz_pp_8x8_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_4x4].filter_hpp = x265_interp_4tap_horiz_pp_4x4_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_32x32].filter_hpp = x265_interp_4tap_horiz_pp_32x32_avx2;
diff -r 57e51fa4dd24 -r c076f0195a36 source/common/x86/ipfilter8.asm
--- a/source/common/x86/ipfilter8.asm Wed Mar 11 14:47:40 2015 +0530
+++ b/source/common/x86/ipfilter8.asm Wed Mar 11 15:30:50 2015 +0530
@@ -2115,6 +2115,159 @@
IPFILTER_LUMA_PS_32xN_AVX2 32 , 24
IPFILTER_LUMA_PS_32xN_AVX2 32 , 8
IPFILTER_LUMA_PS_32xN_AVX2 32 , 64
+
+%macro IPFILTER_LUMA_PS_64xN_AVX2 2
+INIT_YMM avx2
+cglobal interp_8tap_horiz_ps_%1x%2, 6, 7, 8
+%ifdef PIC
+ lea r6, [tab_LumaCoeff]
+ vpbroadcastq m0, [r6 + r4 * 8]
+%else
+ vpbroadcastq m0, [tab_LumaCoeff + r4 * 8]
+%endif
+ mova m6, [tab_Lm + 32]
+ mova m1, [tab_Lm]
+ mov r4, %2 ;height
+ add r3d, r3d
+ vbroadcasti128 m2, [pw_2000]
+ mova m7, [interp8_hps_shuf]
+
+ ; register map
+ ; m0 - interpolate coeff
+ ; m1 , m6 - shuffle order table
+ ; m2 - pw_2000
+
+
+ sub r0, 3
+ test r5d, r5d
+ jz .loop
+ lea r6, [r1 * 3] ; r6 = (N / 2 - 1) * srcStride
+ sub r0, r6 ; r0(src)-r6
+ add r4, 7 ; blkheight += N - 1 (7 - 1 = 6 ; since the last one row not in loop)
+
+.loop
+ ; Row 0
+ vbroadcasti128 m3, [r0] ; [x x x x x A 9 8 7 6 5 4 3 2 1 0]
+ pshufb m4, m3, m6 ; row 0 (col 4 to 7)
+ pshufb m3, m1 ; shuffled based on the col order tab_Lm row 0 (col 0 to 3)
+ pmaddubsw m3, m0
+ pmaddubsw m4, m0
+ pmaddwd m3, [pw_1]
+ pmaddwd m4, [pw_1]
+ packssdw m3, m4
+
+ vbroadcasti128 m4, [r0 + 8]
+ pshufb m5, m4, m6 ;row 0 (col 12 to 15)
+ pshufb m4, m1 ;row 0 (col 8 to 11)
+ pmaddubsw m4, m0
+ pmaddubsw m5, m0
+ pmaddwd m4, [pw_1]
+ pmaddwd m5, [pw_1]
+ packssdw m4, m5
+
+ pmaddwd m3, [pw_1]
+ pmaddwd m4, [pw_1]
+ packssdw m3, m4
+ mova m5, m7
+ vpermd m3, m5, m3
+ psubw m3, m2
+
+ movu [r2], m3 ;row 0
+
+ vbroadcasti128 m3, [r0 + 16]
+ pshufb m4, m3, m6 ; row 0 (col 20 to 23)
+ pshufb m3, m1 ; row 0 (col 16 to 19)
+ pmaddubsw m3, m0
+ pmaddubsw m4, m0
+ pmaddwd m3, [pw_1]
+ pmaddwd m4, [pw_1]
+ packssdw m3, m4
+
+ vbroadcasti128 m4, [r0 + 24]
+ pshufb m5, m4, m6 ;row 0 (col 28 to 31)
+ pshufb m4, m1 ;row 0 (col 24 to 27)
+ pmaddubsw m4, m0
+ pmaddubsw m5, m0
+ pmaddwd m4, [pw_1]
+ pmaddwd m5, [pw_1]
+ packssdw m4, m5
+
+ pmaddwd m3, [pw_1]
+ pmaddwd m4, [pw_1]
+ packssdw m3, m4
+ mova m5, m7
+ vpermd m3, m5, m3
+ psubw m3, m2
+
+ movu [r2 + 32], m3 ;row 0
+
+ vbroadcasti128 m3, [r0 + 32]
+ pshufb m4, m3, m6 ; row 0 (col 36 to 39)
+ pshufb m3, m1 ; row 0 (col 32 to 35)
+ pmaddubsw m3, m0
+ pmaddubsw m4, m0
+ pmaddwd m3, [pw_1]
+ pmaddwd m4, [pw_1]
+ packssdw m3, m4
+
+ vbroadcasti128 m4, [r0 + 40]
+ pshufb m5, m4, m6 ;row 0 (col 44 to 47)
+ pshufb m4, m1 ;row 0 (col 40 to 43)
+ pmaddubsw m4, m0
+ pmaddubsw m5, m0
+ pmaddwd m4, [pw_1]
+ pmaddwd m5, [pw_1]
+ packssdw m4, m5
+
+ pmaddwd m3, [pw_1]
+ pmaddwd m4, [pw_1]
+ packssdw m3, m4
+ mova m5, m7
+ vpermd m3, m5, m3
+ psubw m3, m2
+
+ movu [r2 + 64], m3 ;row 0
+
+ vbroadcasti128 m3, [r0 + 48]
+ pshufb m4, m3, m6 ; row 0 (col 52 to 55)
+ pshufb m3, m1 ; row 0 (col 48 to 51)
+ pmaddubsw m3, m0
+ pmaddubsw m4, m0
+ pmaddwd m3, [pw_1]
+ pmaddwd m4, [pw_1]
+ packssdw m3, m4
+
+ vbroadcasti128 m4, [r0 + 56]
+ pshufb m5, m4, m6 ;row 0 (col 60 to 63)
+ pshufb m4, m1 ;row 0 (col 56 to 59)
+ pmaddubsw m4, m0
+ pmaddubsw m5, m0
+ pmaddwd m4, [pw_1]
+ pmaddwd m5, [pw_1]
+ packssdw m4, m5
+
+ pmaddwd m3, [pw_1]
+ pmaddwd m4, [pw_1]
+ packssdw m3, m4
+ mova m5, m7
+ vpermd m3, m5, m3
+ psubw m3, m2
+
+ movu [r2 + 96], m3 ;row 0
+
+ add r0, r1
+ add r2, r3
+ dec r4d
+ jnz .loop
+
+RET
+%endmacro
+
+IPFILTER_LUMA_PS_64xN_AVX2 64 , 64
+IPFILTER_LUMA_PS_64xN_AVX2 64 , 48
+IPFILTER_LUMA_PS_64xN_AVX2 64 , 32
+IPFILTER_LUMA_PS_64xN_AVX2 64 , 16
+
;--------------------------------------------------------------------------------------------------------------
; void interp_8tap_horiz_pp_%1x%2(pixel *src, intptr_t srcStride, pixel *dst, intptr_t dstStride, int coeffIdx)
;--------------------------------------------------------------------------------------------------------------
More information about the x265-devel
mailing list