[x265] [PATCH] asm: luma_hps[32x8, 32x16, 32x24, 32x32, 32x64] avx2 - improved 6143c->3210c, 9343c->4767c, 12806c->6737c, 16065c->8648c, 29073c->15496c
aasaipriya at multicorewareinc.com
aasaipriya at multicorewareinc.com
Mon Mar 16 06:33:24 CET 2015
- Previous message: [x265] [PATCH] asm: chroma_hpp[32x16, 32x24, 32x8] for i420 - improved 2966c->1647c, 4514c->2627c, 1494c->870c
- Next message: [x265] [PATCH] asm: luma_hps[32x8, 32x16, 32x24, 32x32, 32x64] avx2 - improved 6143c->3210c, 9343c->4767c, 12806c->6737c, 16065c->8648c, 29073c->15496c
- Messages sorted by:
[ date ]
[ thread ]
[ subject ]
[ author ]
# HG changeset patch
# User Aasaipriya Chandran <aasaipriya at multicorewareinc.com>
# Date 1426483989 -19800
# Mon Mar 16 11:03:09 2015 +0530
# Node ID b71432c674193a204de05e8957574431eaba3610
# Parent 19f6ba4dd66147698aa96deb2f364f30a7d63a7e
asm: luma_hps[32x8, 32x16, 32x24, 32x32, 32x64] avx2 - improved 6143c->3210c, 9343c->4767c, 12806c->6737c, 16065c->8648c, 29073c->15496c
diff -r 19f6ba4dd661 -r b71432c67419 source/common/x86/asm-primitives.cpp
--- a/source/common/x86/asm-primitives.cpp Mon Mar 16 10:47:09 2015 +0530
+++ b/source/common/x86/asm-primitives.cpp Mon Mar 16 11:03:09 2015 +0530
@@ -1576,6 +1576,12 @@
p.pu[LUMA_16x32].luma_hps = x265_interp_8tap_horiz_ps_16x32_avx2;
p.pu[LUMA_16x64].luma_hps = x265_interp_8tap_horiz_ps_16x64_avx2;
+ p.pu[LUMA_32x32].luma_hps = x265_interp_8tap_horiz_ps_32x32_avx2;
+ p.pu[LUMA_32x16].luma_hps = x265_interp_8tap_horiz_ps_32x16_avx2;
+ p.pu[LUMA_32x24].luma_hps = x265_interp_8tap_horiz_ps_32x24_avx2;
+ p.pu[LUMA_32x8].luma_hps = x265_interp_8tap_horiz_ps_32x8_avx2;
+ p.pu[LUMA_32x64].luma_hps = x265_interp_8tap_horiz_ps_32x64_avx2;
+
p.chroma[X265_CSP_I420].pu[CHROMA_420_8x8].filter_hpp = x265_interp_4tap_horiz_pp_8x8_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_4x4].filter_hpp = x265_interp_4tap_horiz_pp_4x4_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_32x32].filter_hpp = x265_interp_4tap_horiz_pp_32x32_avx2;
diff -r 19f6ba4dd661 -r b71432c67419 source/common/x86/ipfilter8.asm
--- a/source/common/x86/ipfilter8.asm Mon Mar 16 10:47:09 2015 +0530
+++ b/source/common/x86/ipfilter8.asm Mon Mar 16 11:03:09 2015 +0530
@@ -2038,7 +2038,101 @@
IPFILTER_LUMA_PS_16x_AVX2 16 , 32
IPFILTER_LUMA_PS_16x_AVX2 16 , 64
-
+%macro IPFILTER_LUMA_PS_32xN_AVX2 2
+INIT_YMM avx2
+cglobal interp_8tap_horiz_ps_%1x%2, 6, 7, 8
+%ifdef PIC
+ lea r6, [tab_LumaCoeff]
+ vpbroadcastq m0, [r6 + r4 * 8]
+%else
+ vpbroadcastq m0, [tab_LumaCoeff + r4 * 8]
+%endif
+ mova m6, [tab_Lm + 32]
+ mova m1, [tab_Lm]
+ mov r4d, %2 ;height
+ add r3d, r3d
+ vbroadcasti128 m2, [pw_1]
+ mova m7, [interp8_hps_shuf]
+
+ ; register map
+ ; m0 - interpolate coeff
+ ; m1 , m6 - shuffle order table
+ ; m2 - pw_1
+
+ sub r0, 3
+ test r5d, r5d
+ jz .loop
+ lea r6, [r1 * 3] ; r8 = (N / 2 - 1) * srcStride
+ sub r0, r6
+ add r4d, 7
+
+.loop
+ ; Row 0
+ vbroadcasti128 m3, [r0] ; [x x x x x A 9 8 7 6 5 4 3 2 1 0]
+ pshufb m4, m3, m6 ; row 0 (col 4 to 7)
+ pshufb m3, m1 ; shuffled based on the col order tab_Lm row 0 (col 0 to 3)
+ pmaddubsw m3, m0
+ pmaddubsw m4, m0
+ pmaddwd m3, m2
+ pmaddwd m4, m2
+ packssdw m3, m4
+
+
+ vbroadcasti128 m4, [r0 + 8]
+ pshufb m5, m4, m6 ;row 0 (col 12 to 15)
+ pshufb m4, m1 ;row 0 (col 8 to 11)
+ pmaddubsw m4, m0
+ pmaddubsw m5, m0
+ pmaddwd m4, m2
+ pmaddwd m5, m2
+ packssdw m4, m5
+
+ pmaddwd m3, m2
+ pmaddwd m4, m2
+ packssdw m3, m4
+ vpermd m3, m7, m3
+ psubw m3, [pw_2000]
+
+ movu [r2], m3 ;row 0
+
+ vbroadcasti128 m3, [r0 + 16]
+ pshufb m4, m3, m6 ; row 0 (col 20 to 23)
+ pshufb m3, m1 ; row 0 (col 16 to 19)
+ pmaddubsw m3, m0
+ pmaddubsw m4, m0
+ pmaddwd m3, m2
+ pmaddwd m4, m2
+ packssdw m3, m4
+
+ vbroadcasti128 m4, [r0 + 24]
+ pshufb m5, m4, m6 ;row 0 (col 28 to 31)
+ pshufb m4, m1 ;row 0 (col 24 to 27)
+ pmaddubsw m4, m0
+ pmaddubsw m5, m0
+ pmaddwd m4, m2
+ pmaddwd m5, m2
+ packssdw m4, m5
+
+ pmaddwd m3, m2
+ pmaddwd m4, m2
+ packssdw m3, m4
+ vpermd m3, m7, m3
+ psubw m3, [pw_2000]
+
+ movu [r2 + 32], m3 ;row 0
+
+ add r0, r1
+ add r2, r3
+ dec r4d
+ jnz .loop
+ RET
+%endmacro
+
+IPFILTER_LUMA_PS_32xN_AVX2 32 , 32
+IPFILTER_LUMA_PS_32xN_AVX2 32 , 16
+IPFILTER_LUMA_PS_32xN_AVX2 32 , 24
+IPFILTER_LUMA_PS_32xN_AVX2 32 , 8
+IPFILTER_LUMA_PS_32xN_AVX2 32 , 64
;--------------------------------------------------------------------------------------------------------------
; void interp_8tap_horiz_pp_%1x%2(pixel *src, intptr_t srcStride, pixel *dst, intptr_t dstStride, int coeffIdx)
;--------------------------------------------------------------------------------------------------------------
- Previous message: [x265] [PATCH] asm: chroma_hpp[32x16, 32x24, 32x8] for i420 - improved 2966c->1647c, 4514c->2627c, 1494c->870c
- Next message: [x265] [PATCH] asm: luma_hps[32x8, 32x16, 32x24, 32x32, 32x64] avx2 - improved 6143c->3210c, 9343c->4767c, 12806c->6737c, 16065c->8648c, 29073c->15496c
- Messages sorted by:
[ date ]
[ thread ]
[ subject ]
[ author ]
More information about the x265-devel
mailing list