[x265] [PATCH] asm: luma_hps[48x64] avx2 - improved 42120c->23082c
aasaipriya at multicorewareinc.com
aasaipriya at multicorewareinc.com
Tue Mar 17 06:29:13 CET 2015
# HG changeset patch
# User Aasaipriya Chandran <aasaipriya at multicorewareinc.com>
# Date 1426570146 -19800
# Tue Mar 17 10:59:06 2015 +0530
# Node ID 7673b288c9f3dac27453f1a6d4b0a06fe9202f7a
# Parent 23f703db6aabbea3110a36336880a3f1d45c0b1a
asm: luma_hps[48x64] avx2 - improved 42120c->23082c
diff -r 23f703db6aab -r 7673b288c9f3 source/common/x86/asm-primitives.cpp
--- a/source/common/x86/asm-primitives.cpp Tue Mar 17 10:17:33 2015 +0530
+++ b/source/common/x86/asm-primitives.cpp Tue Mar 17 10:59:06 2015 +0530
@@ -1585,6 +1585,7 @@
p.pu[LUMA_16x64].luma_hps = x265_interp_8tap_horiz_ps_16x64_avx2;
p.pu[LUMA_24x32].luma_hps = x265_interp_8tap_horiz_ps_24x32_avx2;
p.pu[LUMA_12x16].luma_hps = x265_interp_8tap_horiz_ps_12x16_avx2;
+ p.pu[LUMA_48x64].luma_hps = x265_interp_8tap_horiz_ps_48x64_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_8x8].filter_hpp = x265_interp_4tap_horiz_pp_8x8_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_4x4].filter_hpp = x265_interp_4tap_horiz_pp_4x4_avx2;
diff -r 23f703db6aab -r 7673b288c9f3 source/common/x86/ipfilter8.asm
--- a/source/common/x86/ipfilter8.asm Tue Mar 17 10:17:33 2015 +0530
+++ b/source/common/x86/ipfilter8.asm Tue Mar 17 10:59:06 2015 +0530
@@ -17650,3 +17650,119 @@
dec r4d
jnz .loop
RET
+
+INIT_YMM avx2
+cglobal interp_8tap_horiz_ps_48x64, 6, 7, 8
+%ifdef PIC
+ lea r6, [tab_LumaCoeff]
+ vpbroadcastq m0, [r6 + r4 * 8]
+%else
+ vpbroadcastq m0, [tab_LumaCoeff + r4 * 8]
+%endif
+ mova m6, [tab_Lm + 32]
+ mova m1, [tab_Lm]
+ mov r4, 64 ;height
+ add r3d, r3d
+ vbroadcasti128 m2, [pw_2000]
+ mova m7, [pw_1]
+
+ ; register map
+ ; m0 - interpolate coeff
+ ; m1 , m6 - shuffle order table
+ ; m2 - pw_2000
+
+ sub r0, 3
+ test r5d, r5d
+ jz .loop
+ lea r6, [r1 * 3] ; r6 = (N / 2 - 1) * srcStride
+ sub r0, r6 ; r0(src)-r6
+ add r4, 7 ; blkheight += N - 1 (7 - 1 = 6 ; since the last one row not in loop)
+
+.loop
+ ; Row 0
+ vbroadcasti128 m3, [r0] ; [x x x x x A 9 8 7 6 5 4 3 2 1 0]
+ pshufb m4, m3, m6 ; row 0 (col 4 to 7)
+ pshufb m3, m1 ; shuffled based on the col order tab_Lm row 0 (col 0 to 3)
+ pmaddubsw m3, m0
+ pmaddubsw m4, m0
+ pmaddwd m3, m7
+ pmaddwd m4, m7
+ packssdw m3, m4
+
+ vbroadcasti128 m4, [r0 + 8]
+ pshufb m5, m4, m6 ;row 0 (col 12 to 15)
+ pshufb m4, m1 ;row 0 (col 8 to 11)
+ pmaddubsw m4, m0
+ pmaddubsw m5, m0
+ pmaddwd m4, m7
+ pmaddwd m5, m7
+ packssdw m4, m5
+
+ pmaddwd m3, m7
+ pmaddwd m4, m7
+ packssdw m3, m4
+ mova m5, [interp8_hps_shuf]
+ vpermd m3, m5, m3
+ psubw m3, m2
+
+ movu [r2], m3 ;row 0
+
+ vbroadcasti128 m3, [r0 + 16]
+ pshufb m4, m3, m6 ; row 0 (col 20 to 23)
+ pshufb m3, m1 ; row 0 (col 16 to 19)
+ pmaddubsw m3, m0
+ pmaddubsw m4, m0
+ pmaddwd m3, m7
+ pmaddwd m4, m7
+ packssdw m3, m4
+
+ vbroadcasti128 m4, [r0 + 24]
+ pshufb m5, m4, m6 ;row 0 (col 28 to 31)
+ pshufb m4, m1 ;row 0 (col 24 to 27)
+ pmaddubsw m4, m0
+ pmaddubsw m5, m0
+ pmaddwd m4, m7
+ pmaddwd m5, m7
+ packssdw m4, m5
+
+ pmaddwd m3, m7
+ pmaddwd m4, m7
+ packssdw m3, m4
+ mova m5, [interp8_hps_shuf]
+ vpermd m3, m5, m3
+ psubw m3, m2
+
+ movu [r2 + 32], m3 ;row 0
+
+ vbroadcasti128 m3, [r0 + 32]
+ pshufb m4, m3, m6 ; row 0 (col 36 to 39)
+ pshufb m3, m1 ; row 0 (col 32 to 35)
+ pmaddubsw m3, m0
+ pmaddubsw m4, m0
+ pmaddwd m3, m7
+ pmaddwd m4, m7
+ packssdw m3, m4
+
+ vbroadcasti128 m4, [r0 + 40]
+ pshufb m5, m4, m6 ;row 0 (col 44 to 47)
+ pshufb m4, m1 ;row 0 (col 40 to 43)
+ pmaddubsw m4, m0
+ pmaddubsw m5, m0
+ pmaddwd m4, m7
+ pmaddwd m5, m7
+ packssdw m4, m5
+
+ pmaddwd m3, m7
+ pmaddwd m4, m7
+ packssdw m3, m4
+ mova m5, [interp8_hps_shuf]
+ vpermd m3, m5, m3
+ psubw m3, m2
+
+ movu [r2 + 64], m3 ;row 0
+
+ add r0, r1
+ add r2, r3
+ dec r4d
+ jnz .loop
+ RET
More information about the x265-devel
mailing list