[x265] [PATCH 2 of 7] asm: avx2 code for sad[64x32] for 8bpp

[sumalatha at multicorewareinc.com]

# HG changeset patch
# User Sumalatha Polureddy<sumalatha at multicorewareinc.com>
# Date 1426570096 -19800
# Node ID 2b839af3652c78e0e2ee4191711c1c6df52d100f
# Parent  5f185f3b799262f20d8824c3166e09dff488a666
asm: avx2 code for sad[64x32] for 8bpp

see3
sad[64x32]  34.45x   1241.93         42780.37

avx2
sad[64x32]  54.98x   778.15          42781.89

diff -r 5f185f3b7992 -r 2b839af3652c source/common/x86/asm-primitives.cpp
--- a/source/common/x86/asm-primitives.cpp	Tue Mar 17 10:56:07 2015 +0530
+++ b/source/common/x86/asm-primitives.cpp	Tue Mar 17 10:58:16 2015 +0530
@@ -1446,6 +1446,7 @@
 
         p.pu[LUMA_32x32].sad = x265_pixel_sad_32x32_avx2;
         p.pu[LUMA_64x16].sad = x265_pixel_sad_64x16_avx2;
+        p.pu[LUMA_64x32].sad = x265_pixel_sad_64x32_avx2;
 
         p.pu[LUMA_8x4].sad_x3 = x265_pixel_sad_x3_8x4_avx2;
         p.pu[LUMA_8x8].sad_x3 = x265_pixel_sad_x3_8x8_avx2;
diff -r 5f185f3b7992 -r 2b839af3652c source/common/x86/sad-a.asm
--- a/source/common/x86/sad-a.asm	Tue Mar 17 10:56:07 2015 +0530
+++ b/source/common/x86/sad-a.asm	Tue Mar 17 10:58:16 2015 +0530
@@ -4001,4 +4001,44 @@
     movd            eax, xm0
     RET
 
+INIT_YMM avx2
+cglobal pixel_sad_64x32, 4,5,6
+    xorps           m0, m0
+    xorps           m5, m5
+    mov             r4d, 16
+.loop
+    movu           m1, [r0]               ; first 32 of row 0 of pix0
+    movu           m2, [r2]               ; first 32 of row 0 of pix1
+    movu           m3, [r0 + 32]          ; second 32 of row 0 of pix0
+    movu           m4, [r2 + 32]          ; second 32 of row 0 of pix1
+
+    psadbw         m1, m2
+    psadbw         m3, m4
+    paddd          m0, m1
+    paddd          m5, m3
+
+    movu           m1, [r0 + r1]          ; first 32 of row 1 of pix0
+    movu           m2, [r2 + r3]          ; first 32 of row 1 of pix1
+    movu           m3, [r0 + 32 + r1]     ; second 32 of row 1 of pix0
+    movu           m4, [r2 + 32 + r3]     ; second 32 of row 1 of pix1
+
+    psadbw         m1, m2
+    psadbw         m3, m4
+    paddd          m0, m1
+    paddd          m5, m3
+
+    lea     r2,     [r2 + 2 * r3]
+    lea     r0,     [r0 + 2 * r1]
+
+    dec         r4d
+    jnz         .loop
+
+    paddd          m0, m5
+    vextracti128   xm1, m0, 1
+    paddd          xm0, xm1
+    pshufd         xm1, xm0, 2
+    paddd          xm0,xm1
+    movd            eax, xm0
+    RET
+
 %endif