[x265] [PATCH] asm: luma_hps[64x64 , 64x48 , 64x32 , 64x16] avx2 - improved 58533c->28919c, 43517c->22248c, 31254c->15788c, 17540c->8854c
aasaipriya at multicorewareinc.com
aasaipriya at multicorewareinc.com
Mon Mar 23 06:22:09 CET 2015
# HG changeset patch
# User Aasaipriya Chandran <aasaipriya at multicorewareinc.com>
# Date 1427088123 -19800
# Mon Mar 23 10:52:03 2015 +0530
# Node ID 2b52999858b1580efc2967d8fa68fc19787572d7
# Parent cc496665280f9e9e4776327e9a1cc1b2eeffecbc
asm: luma_hps[64x64 , 64x48 , 64x32 , 64x16] avx2 - improved 58533c->28919c, 43517c->22248c, 31254c->15788c, 17540c->8854c
diff -r cc496665280f -r 2b52999858b1 source/common/x86/asm-primitives.cpp
--- a/source/common/x86/asm-primitives.cpp Sun Mar 22 22:16:45 2015 -0400
+++ b/source/common/x86/asm-primitives.cpp Mon Mar 23 10:52:03 2015 +0530
@@ -1643,6 +1643,10 @@
p.pu[LUMA_32x8].luma_hps = x265_interp_8tap_horiz_ps_32x8_avx2;
p.pu[LUMA_32x64].luma_hps = x265_interp_8tap_horiz_ps_32x64_avx2;
p.pu[LUMA_48x64].luma_hps = x265_interp_8tap_horiz_ps_48x64_avx2;
+ p.pu[LUMA_64x64].luma_hps = x265_interp_8tap_horiz_ps_64x64_avx2;
+ p.pu[LUMA_64x48].luma_hps = x265_interp_8tap_horiz_ps_64x48_avx2;
+ p.pu[LUMA_64x32].luma_hps = x265_interp_8tap_horiz_ps_64x32_avx2;
+ p.pu[LUMA_64x16].luma_hps = x265_interp_8tap_horiz_ps_64x16_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_8x8].filter_hpp = x265_interp_4tap_horiz_pp_8x8_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_4x4].filter_hpp = x265_interp_4tap_horiz_pp_4x4_avx2;
diff -r cc496665280f -r 2b52999858b1 source/common/x86/ipfilter8.asm
--- a/source/common/x86/ipfilter8.asm Sun Mar 22 22:16:45 2015 -0400
+++ b/source/common/x86/ipfilter8.asm Mon Mar 23 10:52:03 2015 +0530
@@ -19954,3 +19954,144 @@
IPFILTER_CHROMA_PP_16xN_AVX2 16 , 32
IPFILTER_CHROMA_PP_16xN_AVX2 16 , 12
IPFILTER_CHROMA_PP_16xN_AVX2 16 , 4
+
+%macro IPFILTER_LUMA_PS_64xN_AVX2 1
+INIT_YMM avx2
+cglobal interp_8tap_horiz_ps_64x%1, 4, 7, 8
+ mov r5d, r5m
+ mov r4d, r4m
+%ifdef PIC
+ lea r6, [tab_LumaCoeff]
+ vpbroadcastq m0, [r6 + r4 * 8]
+%else
+ vpbroadcastq m0, [tab_LumaCoeff + r4 * 8]
+%endif
+ mova m6, [tab_Lm + 32]
+ mova m1, [tab_Lm]
+ mov r4d, %1 ;height
+ add r3d, r3d
+ vbroadcasti128 m2, [pw_1]
+ mova m7, [interp8_hps_shuf]
+
+ ; register map
+ ; m0 - interpolate coeff
+ ; m1 , m6 - shuffle order table
+ ; m2 - pw_2000
+
+ sub r0, 3
+ test r5d, r5d
+ jz .label
+ lea r6, [r1 * 3]
+ sub r0, r6 ; r0(src)-r6
+ add r4d, 7 ; blkheight += N - 1
+
+.label
+ lea r6, [pw_2000]
+.loop
+ ; Row 0
+ vbroadcasti128 m3, [r0] ; [x x x x x A 9 8 7 6 5 4 3 2 1 0]
+ pshufb m4, m3, m6 ; row 0 (col 4 to 7)
+ pshufb m3, m1 ; shuffled based on the col order tab_Lm row 0 (col 0 to 3)
+ pmaddubsw m3, m0
+ pmaddubsw m4, m0
+ pmaddwd m3, m2
+ pmaddwd m4, m2
+ packssdw m3, m4
+
+ vbroadcasti128 m4, [r0 + 8]
+ pshufb m5, m4, m6 ;row 0 (col 12 to 15)
+ pshufb m4, m1 ;row 0 (col 8 to 11)
+ pmaddubsw m4, m0
+ pmaddubsw m5, m0
+ pmaddwd m4, m2
+ pmaddwd m5, m2
+ packssdw m4, m5
+ pmaddwd m3, m2
+ pmaddwd m4, m2
+ packssdw m3, m4
+ vpermd m3, m7, m3
+ psubw m3, [r6]
+ movu [r2], m3 ;row 0
+
+ vbroadcasti128 m3, [r0 + 16]
+ pshufb m4, m3, m6 ; row 0 (col 20 to 23)
+ pshufb m3, m1 ; row 0 (col 16 to 19)
+ pmaddubsw m3, m0
+ pmaddubsw m4, m0
+ pmaddwd m3, m2
+ pmaddwd m4, m2
+ packssdw m3, m4
+
+ vbroadcasti128 m4, [r0 + 24]
+ pshufb m5, m4, m6 ;row 0 (col 28 to 31)
+ pshufb m4, m1 ;row 0 (col 24 to 27)
+ pmaddubsw m4, m0
+ pmaddubsw m5, m0
+ pmaddwd m4, m2
+ pmaddwd m5, m2
+ packssdw m4, m5
+ pmaddwd m3, m2
+ pmaddwd m4, m2
+ packssdw m3, m4
+ vpermd m3, m7, m3
+ psubw m3, [r6]
+ movu [r2 + 32], m3 ;row 0
+
+ vbroadcasti128 m3, [r0 + 32]
+ pshufb m4, m3, m6 ; row 0 (col 36 to 39)
+ pshufb m3, m1 ; row 0 (col 32 to 35)
+ pmaddubsw m3, m0
+ pmaddubsw m4, m0
+ pmaddwd m3, m2
+ pmaddwd m4, m2
+ packssdw m3, m4
+
+ vbroadcasti128 m4, [r0 + 40]
+ pshufb m5, m4, m6 ;row 0 (col 44 to 47)
+ pshufb m4, m1 ;row 0 (col 40 to 43)
+ pmaddubsw m4, m0
+ pmaddubsw m5, m0
+ pmaddwd m4, m2
+ pmaddwd m5, m2
+ packssdw m4, m5
+ pmaddwd m3, m2
+ pmaddwd m4, m2
+ packssdw m3, m4
+ vpermd m3, m7, m3
+ psubw m3, [r6]
+ movu [r2 + 64], m3 ;row 0
+ vbroadcasti128 m3, [r0 + 48]
+ pshufb m4, m3, m6 ; row 0 (col 52 to 55)
+ pshufb m3, m1 ; row 0 (col 48 to 51)
+ pmaddubsw m3, m0
+ pmaddubsw m4, m0
+ pmaddwd m3, m2
+ pmaddwd m4, m2
+ packssdw m3, m4
+
+ vbroadcasti128 m4, [r0 + 56]
+ pshufb m5, m4, m6 ;row 0 (col 60 to 63)
+ pshufb m4, m1 ;row 0 (col 56 to 59)
+ pmaddubsw m4, m0
+ pmaddubsw m5, m0
+ pmaddwd m4, m2
+ pmaddwd m5, m2
+ packssdw m4, m5
+ pmaddwd m3, m2
+ pmaddwd m4, m2
+ packssdw m3, m4
+ vpermd m3, m7, m3
+ psubw m3, [r6]
+ movu [r2 + 96], m3 ;row 0
+
+ add r0, r1
+ add r2, r3
+ dec r4d
+ jnz .loop
+ RET
+%endmacro
+
+IPFILTER_LUMA_PS_64xN_AVX2 64
+IPFILTER_LUMA_PS_64xN_AVX2 48
+IPFILTER_LUMA_PS_64xN_AVX2 32
+IPFILTER_LUMA_PS_64xN_AVX2 16
More information about the x265-devel
mailing list