[x265] [PATCH] asm: avx2 10bit code for luma_hpp[32xN],[64xN]
rajesh at multicorewareinc.com
rajesh at multicorewareinc.com
Tue May 19 10:58:09 CEST 2015
# HG changeset patch
# User Rajesh Paulraj<rajesh at multicorewareinc.com>
# Date 1432020349 -19800
# Tue May 19 12:55:49 2015 +0530
# Node ID 569f678f36d731690115b27ed244970f3bc822a8
# Parent d0f54566d1f457f00fc071c47cbb04186e4da99e
asm: avx2 10bit code for luma_hpp[32xN],[64xN]
avx2:
luma_hpp[ 32x8] 8.32x 3627.74 30170.83
luma_hpp[32x16] 8.13x 7919.31 64368.49
luma_hpp[32x32] 7.63x 15286.96 116569.80
luma_hpp[32x24] 7.52x 11697.78 88000.76
luma_hpp[32x64] 7.72x 30244.69 233432.70
luma_hpp[64x16] 7.50x 15080.80 113146.33
luma_hpp[64x32] 8.18x 30264.35 247695.75
luma_hpp[64x48] 7.98x 45546.29 363685.47
luma_hpp[64x64] 8.20x 59435.71 487448.84
sse4:
luma_hpp[ 32x8] 4.99x 6520.85 32525.34
luma_hpp[32x16] 4.94x 13125.30 64830.36
luma_hpp[32x24] 4.61x 19555.56 90103.10
luma_hpp[32x32] 4.53x 25775.25 116649.78
luma_hpp[32x64] 4.59x 52294.73 240239.45
luma_hpp[64x16] 4.48x 26202.95 117409.19
luma_hpp[64x32] 4.53x 51285.01 232277.02
luma_hpp[64x48] 4.30x 80563.75 346052.34
luma_hpp[64x64] 4.58x 106132.23 486381.03
diff -r d0f54566d1f4 -r 569f678f36d7 source/common/x86/asm-primitives.cpp
--- a/source/common/x86/asm-primitives.cpp Tue May 19 12:37:47 2015 +0530
+++ b/source/common/x86/asm-primitives.cpp Tue May 19 12:55:49 2015 +0530
@@ -1398,6 +1398,15 @@
p.pu[LUMA_16x16].luma_hpp = x265_interp_8tap_horiz_pp_16x16_avx2;
p.pu[LUMA_16x32].luma_hpp = x265_interp_8tap_horiz_pp_16x32_avx2;
p.pu[LUMA_16x64].luma_hpp = x265_interp_8tap_horiz_pp_16x64_avx2;
+ p.pu[LUMA_32x8].luma_hpp = x265_interp_8tap_horiz_pp_32x8_avx2;
+ p.pu[LUMA_32x16].luma_hpp = x265_interp_8tap_horiz_pp_32x16_avx2;
+ p.pu[LUMA_32x24].luma_hpp = x265_interp_8tap_horiz_pp_32x24_avx2;
+ p.pu[LUMA_32x32].luma_hpp = x265_interp_8tap_horiz_pp_32x32_avx2;
+ p.pu[LUMA_32x64].luma_hpp = x265_interp_8tap_horiz_pp_32x64_avx2;
+ p.pu[LUMA_64x16].luma_hpp = x265_interp_8tap_horiz_pp_64x16_avx2;
+ p.pu[LUMA_64x32].luma_hpp = x265_interp_8tap_horiz_pp_64x32_avx2;
+ p.pu[LUMA_64x48].luma_hpp = x265_interp_8tap_horiz_pp_64x48_avx2;
+ p.pu[LUMA_64x64].luma_hpp = x265_interp_8tap_horiz_pp_64x64_avx2;
if (cpuMask & X265_CPU_BMI2)
p.scanPosLast = x265_scanPosLast_avx2_bmi2;
diff -r d0f54566d1f4 -r 569f678f36d7 source/common/x86/ipfilter16.asm
--- a/source/common/x86/ipfilter16.asm Tue May 19 12:37:47 2015 +0530
+++ b/source/common/x86/ipfilter16.asm Tue May 19 12:55:49 2015 +0530
@@ -1056,6 +1056,112 @@
FILTER_HOR_LUMA_W16 32
FILTER_HOR_LUMA_W16 64
+;-------------------------------------------------------------------------------------------------------------
+; void interp_8tap_horiz_pp(pixel *src, intptr_t srcStride, pixel *dst, intptr_t dstStride, int coeffIdx
+;-------------------------------------------------------------------------------------------------------------
+%macro FILTER_HOR_LUMA_W32 2
+INIT_YMM avx2
+cglobal interp_8tap_horiz_pp_%1x%2, 4,6,8
+ add r1d, r1d
+ add r3d, r3d
+ sub r0, 6
+ mov r4d, r4m
+ shl r4d, 4
+%ifdef PIC
+ lea r5, [tab_LumaCoeff]
+ vpbroadcastq m0, [r5 + r4]
+ vpbroadcastq m1, [r5 + r4 + 8]
+%else
+ vpbroadcastq m0, [tab_LumaCoeff + r4]
+ vpbroadcastq m1, [tab_LumaCoeff + r4 + 8]
+%endif
+ mova m3, [interp8_hpp_shuf]
+ mova m7, [pd_32]
+ pxor m2, m2
+
+ ; register map
+ ; m0 , m1 interpolate coeff
+
+ mov r4d, %2
+
+.loop:
+%assign x 0
+%rep %1/16
+ vbroadcasti128 m4, [r0 + x]
+ vbroadcasti128 m5, [r0 + 8 + x]
+ pshufb m4, m3
+ pshufb m5, m3
+
+ pmaddwd m4, m0
+ pmaddwd m5, m1
+ paddd m4, m5
+
+ vbroadcasti128 m5, [r0 + 8 + x]
+ vbroadcasti128 m6, [r0 + 16 + x]
+ pshufb m5, m3
+ pshufb m6, m3
+
+ pmaddwd m5, m0
+ pmaddwd m6, m1
+ paddd m5, m6
+
+ phaddd m4, m5
+ vpermq m4, m4, q3120
+ paddd m4, m7
+ psrad m4, 6
+
+ packusdw m4, m4
+ vpermq m4, m4, q2020
+ CLIPW m4, m2, [pw_pixel_max]
+ movu [r2 + x], xm4
+
+ vbroadcasti128 m4, [r0 + 16 + x]
+ vbroadcasti128 m5, [r0 + 24 + x]
+ pshufb m4, m3
+ pshufb m5, m3
+
+ pmaddwd m4, m0
+ pmaddwd m5, m1
+ paddd m4, m5
+
+ vbroadcasti128 m5, [r0 + 24 + x]
+ vbroadcasti128 m6, [r0 + 32 + x]
+ pshufb m5, m3
+ pshufb m6, m3
+
+ pmaddwd m5, m0
+ pmaddwd m6, m1
+ paddd m5, m6
+
+ phaddd m4, m5
+ vpermq m4, m4, q3120
+ paddd m4, m7
+ psrad m4, 6
+
+ packusdw m4, m4
+ vpermq m4, m4, q2020
+ CLIPW m4, m2, [pw_pixel_max]
+ movu [r2 + 16 + x], xm4
+
+%assign x x+32
+%endrep
+
+ add r2, r3
+ add r0, r1
+ dec r4d
+ jnz .loop
+ RET
+%endmacro
+FILTER_HOR_LUMA_W32 32, 8
+FILTER_HOR_LUMA_W32 32, 16
+FILTER_HOR_LUMA_W32 32, 24
+FILTER_HOR_LUMA_W32 32, 32
+FILTER_HOR_LUMA_W32 32, 64
+FILTER_HOR_LUMA_W32 64, 16
+FILTER_HOR_LUMA_W32 64, 32
+FILTER_HOR_LUMA_W32 64, 48
+FILTER_HOR_LUMA_W32 64, 64
+
;-----------------------------------------------------------------------------
; void interp_4tap_horiz_%3_%1x%2(pixel *src, intptr_t srcStride, pixel *dst, intptr_t dstStride, int coeffIdx)
;-----------------------------------------------------------------------------
More information about the x265-devel
mailing list