[x265] [PATCH] asm: 10bpp avx2 code for intra_pred_ang32x32 mode 6 & 30
dnyaneshwar at multicorewareinc.com
dnyaneshwar at multicorewareinc.com
Wed Jun 10 10:36:53 CEST 2015
# HG changeset patch
# User Dnyaneshwar G <dnyaneshwar at multicorewareinc.com>
# Date 1433920584 -19800
# Wed Jun 10 12:46:24 2015 +0530
# Node ID 598183ef071dcf88c3a5d48b9d2d6a5063b7b400
# Parent 2188ac83f8f59c9e68bc90c540f3951b74f2a32a
asm: 10bpp avx2 code for intra_pred_ang32x32 mode 6 & 30
performance improvement over SSE:
intra_ang_32x32[ 6] 7864c->4202c, 46%
intra_ang_32x32[30] 5984c->2924c, 51%
diff -r 2188ac83f8f5 -r 598183ef071d source/common/x86/asm-primitives.cpp
--- a/source/common/x86/asm-primitives.cpp Wed Jun 10 11:07:56 2015 +0530
+++ b/source/common/x86/asm-primitives.cpp Wed Jun 10 12:46:24 2015 +0530
@@ -1260,6 +1260,8 @@
p.cu[BLOCK_32x32].intra_pred[3] = x265_intra_pred_ang32_3_avx2;
p.cu[BLOCK_32x32].intra_pred[4] = x265_intra_pred_ang32_4_avx2;
p.cu[BLOCK_32x32].intra_pred[5] = x265_intra_pred_ang32_5_avx2;
+ p.cu[BLOCK_32x32].intra_pred[6] = x265_intra_pred_ang32_6_avx2;
+ p.cu[BLOCK_32x32].intra_pred[30] = x265_intra_pred_ang32_30_avx2;
p.cu[BLOCK_32x32].intra_pred[31] = x265_intra_pred_ang32_31_avx2;
p.cu[BLOCK_32x32].intra_pred[32] = x265_intra_pred_ang32_32_avx2;
p.cu[BLOCK_32x32].intra_pred[33] = x265_intra_pred_ang32_33_avx2;
diff -r 2188ac83f8f5 -r 598183ef071d source/common/x86/intrapred.h
--- a/source/common/x86/intrapred.h Wed Jun 10 11:07:56 2015 +0530
+++ b/source/common/x86/intrapred.h Wed Jun 10 12:46:24 2015 +0530
@@ -279,6 +279,7 @@
void x265_intra_pred_ang32_3_avx2(pixel* dst, intptr_t dstStride, const pixel* srcPix, int dirMode, int bFilter);
void x265_intra_pred_ang32_4_avx2(pixel* dst, intptr_t dstStride, const pixel* srcPix, int dirMode, int bFilter);
void x265_intra_pred_ang32_5_avx2(pixel* dst, intptr_t dstStride, const pixel* srcPix, int dirMode, int bFilter);
+void x265_intra_pred_ang32_6_avx2(pixel* dst, intptr_t dstStride, const pixel* srcPix, int dirMode, int bFilter);
void x265_intra_pred_ang32_26_avx2(pixel* dst, intptr_t dstStride, const pixel* srcPix, int dirMode, int bFilter);
void x265_intra_pred_ang32_27_avx2(pixel* dst, intptr_t dstStride, const pixel* srcPix, int dirMode, int bFilter);
void x265_intra_pred_ang32_28_avx2(pixel* dst, intptr_t dstStride, const pixel* srcPix, int dirMode, int bFilter);
diff -r 2188ac83f8f5 -r 598183ef071d source/common/x86/intrapred16.asm
--- a/source/common/x86/intrapred16.asm Wed Jun 10 11:07:56 2015 +0530
+++ b/source/common/x86/intrapred16.asm Wed Jun 10 12:46:24 2015 +0530
@@ -13770,6 +13770,215 @@
call ang32_mode_5_31
RET
+
+;; angle 32, modes 6 and 30
+cglobal ang32_mode_6_30
+ test r6d, r6d
+
+ movu m0, [r2 + 2] ; [16 15 14 13 12 11 10 9 8 7 6 5 4 3 2 1]
+ movu m1, [r2 + 4] ; [17 16 15 14 13 12 11 10 9 8 7 6 5 4 3 2]
+
+ punpcklwd m3, m0, m1 ; [13 12 12 11 11 10 10 9 5 4 4 3 3 2 2 1]
+ punpckhwd m0, m1 ; [17 16 16 15 15 14 14 13 9 8 8 7 7 6 6 5]
+
+ movu m1, [r2 + 18] ; [24 23 22 21 20 19 18 17 16 15 14 13 12 11 10 9]
+ movu m4, [r2 + 20] ; [25 24 23 22 21 20 19 18 17 16 15 14 13 12 11 10]
+ punpcklwd m2, m1, m4 ; [21 20 20 19 19 18 18 17 13 12 12 11 11 10 10 9]
+ punpckhwd m1, m4 ; [25 24 24 23 23 22 22 21 17 16 16 15 15 14 14 13]
+
+ pmaddwd m4, m3, [r3 + 14 * 32] ; [29]
+ paddd m4, [pd_16]
+ psrld m4, 5
+ pmaddwd m5, m0, [r3 + 14 * 32]
+ paddd m5, [pd_16]
+ psrld m5, 5
+ packusdw m4, m5
+
+ palignr m6, m0, m3, 4
+ pmaddwd m5, m6, [r3 - 5 * 32] ; [10]
+ paddd m5, [pd_16]
+ psrld m5, 5
+ palignr m7, m2, m0, 4
+ pmaddwd m8, m7, [r3 - 5 * 32]
+ paddd m8, [pd_16]
+ psrld m8, 5
+ packusdw m5, m8
+
+ pmaddwd m6, [r3 + 8 * 32] ; [23]
+ paddd m6, [pd_16]
+ psrld m6, 5
+ pmaddwd m7, [r3 + 8 * 32]
+ paddd m7, [pd_16]
+ psrld m7, 5
+ packusdw m6, m7
+
+ palignr m9, m0, m3, 8
+ pmaddwd m7, m9, [r3 - 11 * 32] ; [4]
+ paddd m7, [pd_16]
+ psrld m7, 5
+ palignr m12, m2, m0, 8
+ pmaddwd m11, m12, [r3 - 11 * 32]
+ paddd m11, [pd_16]
+ psrld m11, 5
+ packusdw m7, m11
+
+ pmaddwd m8, m9, [r3 + 2 * 32] ; [17]
+ paddd m8, [pd_16]
+ psrld m8, 5
+ pmaddwd m10, m12, [r3 + 2 * 32]
+ paddd m10, [pd_16]
+ psrld m10, 5
+ packusdw m8, m10
+
+ pmaddwd m9, [r3 + 15 * 32] ; [30]
+ paddd m9, [pd_16]
+ psrld m9, 5
+ pmaddwd m12, [r3 + 15 * 32]
+ paddd m12, [pd_16]
+ psrld m12, 5
+ packusdw m9, m12
+
+ palignr m11, m0, m3, 12
+ pmaddwd m10, m11, [r3 - 4 * 32] ; [11]
+ paddd m10, [pd_16]
+ psrld m10, 5
+ palignr m12, m2, m0, 12
+ pmaddwd m3, m12, [r3 - 4 * 32]
+ paddd m3, [pd_16]
+ psrld m3, 5
+ packusdw m10, m3
+
+ pmaddwd m11, [r3 + 9 * 32] ; [24]
+ paddd m11, [pd_16]
+ psrld m11, 5
+ pmaddwd m12, [r3 + 9 * 32]
+ paddd m12, [pd_16]
+ psrld m12, 5
+ packusdw m11, m12
+
+ TRANSPOSE_STORE_AVX2 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 0
+
+ pmaddwd m4, m0, [r3 - 10 * 32] ; [5]
+ paddd m4, [pd_16]
+ psrld m4, 5
+ pmaddwd m5, m2, [r3 - 10 * 32]
+ paddd m5, [pd_16]
+ psrld m5, 5
+ packusdw m4, m5
+
+ pmaddwd m5, m0, [r3 + 3 * 32] ; [18]
+ paddd m5, [pd_16]
+ psrld m5, 5
+ pmaddwd m3, m2, [r3 + 3 * 32]
+ paddd m3, [pd_16]
+ psrld m3, 5
+ packusdw m5, m3
+
+ pmaddwd m6, m0, [r3 + 16 * 32] ; [31]
+ paddd m6, [pd_16]
+ psrld m6, 5
+ pmaddwd m7, m2, [r3 + 16 * 32]
+ paddd m7, [pd_16]
+ psrld m7, 5
+ packusdw m6, m7
+
+ palignr m8, m2, m0, 4
+ pmaddwd m7, m8, [r3 - 3 * 32] ; [12]
+ paddd m7, [pd_16]
+ psrld m7, 5
+ palignr m9, m1, m2, 4
+ pmaddwd m3, m9, [r3 - 3 * 32]
+ paddd m3, [pd_16]
+ psrld m3, 5
+ packusdw m7, m3
+
+ pmaddwd m8, [r3 + 10 * 32] ; [25]
+ paddd m8, [pd_16]
+ psrld m8, 5
+ pmaddwd m9, [r3 + 10 * 32]
+ paddd m9, [pd_16]
+ psrld m9, 5
+ packusdw m8, m9
+
+ palignr m10, m2, m0, 8
+ pmaddwd m9, m10, [r3 - 9 * 32] ; [6]
+ paddd m9, [pd_16]
+ psrld m9, 5
+ palignr m12, m1, m2, 8
+ pmaddwd m3, m12, [r3 - 9 * 32]
+ paddd m3, [pd_16]
+ psrld m3, 5
+ packusdw m9, m3
+
+ pmaddwd m10, [r3 + 4 * 32] ; [19]
+ paddd m10, [pd_16]
+ psrld m10, 5
+ pmaddwd m12, [r3 + 4 * 32]
+ paddd m12, [pd_16]
+ psrld m12, 5
+ packusdw m10, m12
+
+ palignr m11, m2, m0, 12
+ pmaddwd m11, [r3 - 15 * 32] ; [0]
+ paddd m11, [pd_16]
+ psrld m11, 5
+ palignr m3, m1, m2, 12
+ pmaddwd m3, [r3 - 15 * 32]
+ paddd m3, [pd_16]
+ psrld m3, 5
+ packusdw m11, m3
+ TRANSPOSE_STORE_AVX2 4, 5, 6, 7, 8, 9, 10, 11, 0, 1, 16
+ ret
+
+cglobal intra_pred_ang32_6, 3,8,14
+ add r2, 128
+ xor r6d, r6d
+ lea r3, [ang_table_avx2 + 15 * 32]
+ add r1d, r1d
+ lea r4, [r1 * 3]
+ lea r7, [r0 + 8 * r1]
+
+ call ang16_mode_6_30
+
+ add r2, 12
+ lea r0, [r0 + 32]
+
+ call ang32_mode_6_30
+
+ add r2, 20
+ lea r0, [r7 + 8 * r1]
+
+ call ang16_mode_6_30
+
+ add r2, 12
+ lea r0, [r0 + 32]
+
+ call ang32_mode_6_30
+ RET
+
+cglobal intra_pred_ang32_30, 3,7,14
+ xor r6d, r6d
+ inc r6d
+ lea r3, [ang_table_avx2 + 15 * 32]
+ add r1d, r1d
+ lea r4, [r1 * 3]
+ lea r5, [r0 + 32]
+
+ call ang16_mode_6_30
+
+ add r2, 12
+
+ call ang32_mode_6_30
+
+ add r2, 20
+ mov r0, r5
+
+ call ang16_mode_6_30
+
+ add r2, 12
+
+ call ang32_mode_6_30
+ RET
;-------------------------------------------------------------------------------------------------------
; end of avx2 code for intra_pred_ang32 mode 2 to 34
;-------------------------------------------------------------------------------------------------------
More information about the x265-devel
mailing list