[x265] [PATCH] asm: luma_hps[32x8, 32x16, 32x24, 32x32, 32x64] avx2 - improved 6143c->3007c, 9343c->4767c, 12806c->6238c, 16065c->8125c, 29073c->14615c
aasaipriya at multicorewareinc.com
aasaipriya at multicorewareinc.com
Fri Mar 20 05:37:24 CET 2015
# HG changeset patch
# User Aasaipriya Chandran <aasaipriya at multicorewareinc.com>
# Date 1426826226 -19800
# Fri Mar 20 10:07:06 2015 +0530
# Node ID da67b5a736ee27ca5825c5f552cd2fd7b760b242
# Parent ee667a53aeb475c5d14a75f1d537111e5654ff79
asm: luma_hps[32x8, 32x16, 32x24, 32x32, 32x64] avx2 - improved 6143c->3007c, 9343c->4767c, 12806c->6238c, 16065c->8125c, 29073c->14615c
diff -r ee667a53aeb4 -r da67b5a736ee source/common/x86/asm-primitives.cpp
--- a/source/common/x86/asm-primitives.cpp Thu Mar 19 20:56:29 2015 -0500
+++ b/source/common/x86/asm-primitives.cpp Fri Mar 20 10:07:06 2015 +0530
@@ -1599,6 +1599,12 @@
p.pu[LUMA_16x32].luma_hps = x265_interp_8tap_horiz_ps_16x32_avx2;
p.pu[LUMA_16x64].luma_hps = x265_interp_8tap_horiz_ps_16x64_avx2;
+ p.pu[LUMA_32x32].luma_hps = x265_interp_8tap_horiz_ps_32x32_avx2;
+ p.pu[LUMA_32x16].luma_hps = x265_interp_8tap_horiz_ps_32x16_avx2;
+ p.pu[LUMA_32x24].luma_hps = x265_interp_8tap_horiz_ps_32x24_avx2;
+ p.pu[LUMA_32x8].luma_hps = x265_interp_8tap_horiz_ps_32x8_avx2;
+ p.pu[LUMA_32x64].luma_hps = x265_interp_8tap_horiz_ps_32x64_avx2;
+
p.chroma[X265_CSP_I420].pu[CHROMA_420_8x8].filter_hpp = x265_interp_4tap_horiz_pp_8x8_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_4x4].filter_hpp = x265_interp_4tap_horiz_pp_4x4_avx2;
p.chroma[X265_CSP_I420].pu[CHROMA_420_32x32].filter_hpp = x265_interp_4tap_horiz_pp_32x32_avx2;
diff -r ee667a53aeb4 -r da67b5a736ee source/common/x86/ipfilter8.asm
--- a/source/common/x86/ipfilter8.asm Thu Mar 19 20:56:29 2015 -0500
+++ b/source/common/x86/ipfilter8.asm Fri Mar 20 10:07:06 2015 +0530
@@ -18535,3 +18535,104 @@
IPFILTER_CHROMA_PP_4xN_AVX2 4 , 8
IPFILTER_CHROMA_PP_4xN_AVX2 4 , 16
+
+%macro IPFILTER_LUMA_PS_32xN_AVX2 2
+INIT_YMM avx2
+cglobal interp_8tap_horiz_ps_%1x%2, 4, 7, 8
+ mov r5d, r5m
+ mov r4d, r4m
+%ifdef PIC
+ lea r6, [tab_LumaCoeff]
+ vpbroadcastq m0, [r6 + r4 * 8]
+%else
+ vpbroadcastq m0, [tab_LumaCoeff + r4 * 8]
+%endif
+ mova m6, [tab_Lm + 32]
+ mova m1, [tab_Lm]
+ mov r4d, %2 ;height
+ add r3d, r3d
+ vbroadcasti128 m2, [pw_1]
+ mova m7, [interp8_hps_shuf]
+
+ ; register map
+ ; m0 - interpolate coeff
+ ; m1 , m6 - shuffle order table
+ ; m2 - pw_1
+
+
+ sub r0, 3
+ test r5d, r5d
+ jz .label
+ lea r6, [r1 * 3] ; r8 = (N / 2 - 1) * srcStride
+ sub r0, r6
+ add r4d, 7
+
+.label
+ lea r6, [pw_2000]
+.loop
+ ; Row 0
+ vbroadcasti128 m3, [r0] ; [x x x x x A 9 8 7 6 5 4 3 2 1 0]
+ pshufb m4, m3, m6 ; row 0 (col 4 to 7)
+ pshufb m3, m1 ; shuffled based on the col order tab_Lm row 0 (col 0 to 3)
+ pmaddubsw m3, m0
+ pmaddubsw m4, m0
+ pmaddwd m3, m2
+ pmaddwd m4, m2
+ packssdw m3, m4
+
+
+ vbroadcasti128 m4, [r0 + 8]
+ pshufb m5, m4, m6 ;row 0 (col 12 to 15)
+ pshufb m4, m1 ;row 0 (col 8 to 11)
+ pmaddubsw m4, m0
+ pmaddubsw m5, m0
+ pmaddwd m4, m2
+ pmaddwd m5, m2
+ packssdw m4, m5
+
+ pmaddwd m3, m2
+ pmaddwd m4, m2
+ packssdw m3, m4
+ vpermd m3, m7, m3
+ psubw m3, [r6]
+
+ movu [r2], m3 ;row 0
+
+ vbroadcasti128 m3, [r0 + 16]
+ pshufb m4, m3, m6 ; row 0 (col 20 to 23)
+ pshufb m3, m1 ; row 0 (col 16 to 19)
+ pmaddubsw m3, m0
+ pmaddubsw m4, m0
+ pmaddwd m3, m2
+ pmaddwd m4, m2
+ packssdw m3, m4
+
+ vbroadcasti128 m4, [r0 + 24]
+ pshufb m5, m4, m6 ;row 0 (col 28 to 31)
+ pshufb m4, m1 ;row 0 (col 24 to 27)
+ pmaddubsw m4, m0
+ pmaddubsw m5, m0
+ pmaddwd m4, m2
+ pmaddwd m5, m2
+ packssdw m4, m5
+
+ pmaddwd m3, m2
+ pmaddwd m4, m2
+ packssdw m3, m4
+ vpermd m3, m7, m3
+ psubw m3, [r6]
+
+ movu [r2 + 32], m3 ;row 0
+
+ add r0, r1
+ add r2, r3
+ dec r4d
+ jnz .loop
+ RET
+%endmacro
+
+IPFILTER_LUMA_PS_32xN_AVX2 32 , 32
+IPFILTER_LUMA_PS_32xN_AVX2 32 , 16
+IPFILTER_LUMA_PS_32xN_AVX2 32 , 24
+IPFILTER_LUMA_PS_32xN_AVX2 32 , 8
+IPFILTER_LUMA_PS_32xN_AVX2 32 , 64
More information about the x265-devel
mailing list